1 files changed, 76 insertions, 0 deletions
diff --git a/dev-util/debugedit/debugedit-5.3.ebuild b/dev-util/debugedit/debugedit-5.3.ebuild
new file mode 100644
index 000000000000..822ec217386d
--- /dev/null
+++ b/dev-util/debugedit/debugedit-5.3.ebuild
@@ -0,0 +1,76 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit multiprocessing optfeature verify-sig toolchain-funcs
+
+DESCRIPTION="Create debuginfo and source file distributions"
+HOMEPAGE="https://sourceware.org/debugedit/"
+SRC_URI="
+	https://sourceware.org/ftp/debugedit/${PV}/${P}.tar.xz
+	verify-sig? ( https://sourceware.org/ftp/debugedit/${PV}/${P}.tar.xz.sig )
+"
+
+LICENSE="GPL-3+ GPL-2+ LGPL-2+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+DEPEND="
+	>=dev-libs/elfutils-0.176-r1:=
+	>=dev-libs/xxhash-0.8:=
+	elibc_musl? ( >=sys-libs/error-standalone-2.0 )
+"
+RDEPEND="
+	${DEPEND}
+"
+BDEPEND="
+	sys-apps/help2man
+	virtual/pkgconfig
+	test? (
+		app-alternatives/cpio
+		dev-debug/gdb
+		sys-devel/dwz
+	)
+	verify-sig? (
+		>=sec-keys/openpgp-keys-debugedit-20260311
+	)
+"
+
+VERIFY_SIG_OPENPGP_KEY_PATH=/usr/share/openpgp-keys/debugedit.gpg
+
+src_configure() {
+	tc-export PKG_CONFIG
+
+	if use elibc_musl; then
+		export CFLAGS="${CFLAGS} $(${PKG_CONFIG} --cflags error-standalone)"
+		export LIBS="${LIBS} $(${PKG_CONFIG} --libs error-standalone)"
+	fi
+
+	local myconf=(
+		# avoid bunch of BDEPs, sigh
+		DWZ=dwz
+		ac_cv_dwz_j=yes
+		HAS_CPIO=yes
+		HAS_EU_STRIP=yes
+		HAS_XZ=yes
+		HAS_GDB_ADD_INDEX=yes
+		HAS_EU_ELFLINT=yes
+
+		# We don't want to effectively bundle xxhash. It fails to
+		# build with -Og and such too (bug #956627).
+		--disable-inlined-xxhash
+	)
+	econf "${myconf[@]}"
+}
+
+src_test() {
+	local -x CCACHE_DISABLE=1
+	emake -Onone check TESTSUITEFLAGS="--jobs=$(get_makeopts_jobs)"
+}
+
+pkg_postinst() {
+	 optfeature "dwz support in find-debuginfo" sys-devel/dwz
+}