5 files changed, 133 insertions, 0 deletions
diff --git a/dev-util/edb-debugger/Manifest b/dev-util/edb-debugger/Manifest
new file mode 100644
index 000000000000..8b65820d3eff
--- /dev/null
+++ b/dev-util/edb-debugger/Manifest
@@ -0,0 +1 @@
+DIST edb-debugger-1.2.0.tgz 608773 BLAKE2B d67136b3bfb153f0e5ba0aef514756f39d63692636adcad3569e79237613004f2a4c425b4bed875408473a7caa6280b3bfc590e8eeb4beb5bafaa2326da892bc SHA512 c04b8d3972497ac170c740f2625301ee7d3ea52b81b29084628aa0091d7cd7df12a34ae707be629cde6e0dea54254bfde25e290aba1d6bad2635eff704282ea9
diff --git a/dev-util/edb-debugger/edb-debugger-1.2.0.ebuild b/dev-util/edb-debugger/edb-debugger-1.2.0.ebuild
new file mode 100644
index 000000000000..9fd3eb915ec0
--- /dev/null
+++ b/dev-util/edb-debugger/edb-debugger-1.2.0.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake
+
+DESCRIPTION="edb is a cross platform x86/x86-64 debugger, inspired by Ollydbg"
+HOMEPAGE="https://github.com/eteran/edb-debugger"
+SRC_URI="https://github.com/eteran/edb-debugger/releases/download/${PV}/edb-debugger-${PV}.tgz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="graphviz"
+
+RDEPEND="
+	dev-libs/capstone:=
+	dev-libs/double-conversion
+	dev-qt/qtconcurrent:5
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtnetwork:5
+	dev-qt/qtsvg:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtxml:5
+	dev-qt/qtxmlpatterns:5
+	graphviz? ( media-gfx/graphviz )
+"
+
+DEPEND="
+	dev-libs/boost
+	virtual/pkgconfig
+	${RDEPEND}
+"
+
+PATCHES=("${FILESDIR}"/${PN}-1.2.0-qt-5.15.patch)
+
+S=${WORKDIR}/${PN}
+
+src_prepare() {
+	#Make the desktop's entries somewhat better
+	sed -i -e 's/GenericName=edb debugger/GenericName=Evan\x27s Debugger/' edb.desktop || die
+	sed -i -e 's/Comment=edb debugger/Comment=edb is a cross platform x86\/x86-64 debugger/' edb.desktop || die
+
+	if ! use graphviz; then
+		sed -i -e '/pkg_check_modules(GRAPHVIZ/d' CMakeLists.txt || die
+	fi
+
+	cmake_src_prepare
+}
diff --git a/dev-util/edb-debugger/edb-debugger-9999.ebuild b/dev-util/edb-debugger/edb-debugger-9999.ebuild
new file mode 100644
index 000000000000..6ff5cb3e1c08
--- /dev/null
+++ b/dev-util/edb-debugger/edb-debugger-9999.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake git-r3
+
+DESCRIPTION="edb is a cross platform x86/x86-64 debugger, inspired by Ollydbg"
+HOMEPAGE="https://github.com/eteran/edb-debugger"
+EGIT_REPO_URI="https://github.com/eteran/edb-debugger.git"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS=""
+IUSE="graphviz jumbo-build"
+
+RDEPEND="
+	dev-libs/capstone:=
+	dev-libs/double-conversion
+	dev-qt/qtconcurrent:5
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtnetwork:5
+	dev-qt/qtsvg:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtxml:5
+	dev-qt/qtxmlpatterns:5
+	graphviz? ( media-gfx/graphviz )
+"
+
+DEPEND="
+	dev-libs/boost
+	virtual/pkgconfig
+	${RDEPEND}
+"
+
+src_prepare() {
+	if ! use graphviz; then
+		sed -i -e '/pkg_check_modules(GRAPHVIZ/d' CMakeLists.txt || die
+	fi
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_JUMBO=$(usex jumbo-build)
+	)
+	cmake_src_configure
+}
diff --git a/dev-util/edb-debugger/files/edb-debugger-1.2.0-qt-5.15.patch b/dev-util/edb-debugger/files/edb-debugger-1.2.0-qt-5.15.patch
new file mode 100644
index 000000000000..795cb8fce681
--- /dev/null
+++ b/dev-util/edb-debugger/files/edb-debugger-1.2.0-qt-5.15.patch
@@ -0,0 +1,20 @@
+https://bugs.gentoo.org/727530
+https://github.com/eteran/edb-debugger/pull/766
+
+Fix build failure on qt-5.15. Typical build error is:
+
+src/widgets/QDisassemblyView.cpp:1503:17:
+  error: aggregate ‘QPainterPath path’ has incomplete type and cannot be defined
+ 1503 |    QPainterPath path;
+      |                 ^~~~
+
+--- a/src/widgets/QDisassemblyView.h
++++ b/src/widgets/QDisassemblyView.h
+@@ -25,6 +25,7 @@ along with this program.  If not, see <http://www.gnu.org/licenses/>.
+ #include <QAbstractScrollArea>
+ #include <QAbstractSlider>
+ #include <QCache>
++#include <QPainterPath>
+ #include <QPixmap>
+ #include <QSvgRenderer>
+ 
diff --git a/dev-util/edb-debugger/metadata.xml b/dev-util/edb-debugger/metadata.xml
new file mode 100644
index 000000000000..5483cfa6e475
--- /dev/null
+++ b/dev-util/edb-debugger/metadata.xml
@@ -0,0 +1,12 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>slyfox@gentoo.org</email>
+		<name>Sergei Trofimovich</name>
+	</maintainer>
+	<use>
+		<flag name="jumbo-build">Experimental jumbo (also known as unity) build capability</flag>
+	</use>
+	<origin>gentoo-staging</origin>
+</pkgmetadata>