3 files changed, 64 insertions, 5 deletions
diff --git a/dev-util/global/global-6.6.13.ebuild b/dev-util/global/global-6.6.13.ebuild
index 6f779f20b9fd..992a1626312f 100644
--- a/dev-util/global/global-6.6.13.ebuild
+++ b/dev-util/global/global-6.6.13.ebuild
@@ -12,7 +12,7 @@ SRC_URI="mirror://gnu/${PN}/${P}.tar.gz"
 
 LICENSE="GPL-3+"
 SLOT="0"
-KEYWORDS="~amd64 ~ppc ~x86"
+KEYWORDS="~amd64 ppc ~x86"
 IUSE="doc emacs"
 REQUIRED_USE="${PYTHON_REQUIRED_USE}"
 
diff --git a/dev-util/include-what-you-use/include-what-you-use-0.23-r1.ebuild b/dev-util/include-what-you-use/include-what-you-use-0.23-r1.ebuild
new file mode 100644
index 000000000000..8dac9491fc31
--- /dev/null
+++ b/dev-util/include-what-you-use/include-what-you-use-0.23-r1.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{9,10,11,12,13} )
+LLVM_COMPAT=( 19 )
+
+inherit cmake llvm-r1 python-single-r1
+
+DESCRIPTION="Find unused include directives in C/C++ programs"
+HOMEPAGE="https://include-what-you-use.org/"
+SRC_URI="
+	https://github.com/${PN}/${PN}/archive/${PV}.tar.gz
+		-> ${P}.tar.gz
+"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+RDEPEND="
+	$(llvm_gen_dep '
+		llvm-core/clang:${LLVM_SLOT}=
+		llvm-core/llvm:${LLVM_SLOT}=
+	')
+	${PYTHON_DEPS}
+"
+DEPEND="${RDEPEND}"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+pkg_setup() {
+	llvm-r1_pkg_setup
+	python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	cmake_src_prepare
+	python_fix_shebang .
+}
+
+src_configure() {
+	local mycmakeargs=(
+		# Note [llvm install path]
+		# Unfortunately all binaries using clang driver
+		# have to reside at the same path depth as
+		# 'clang' binary itself. See bug #625972
+		# Thus as a hack we install it to the same directory
+		# as llvm/clang itself.
+		-DCMAKE_INSTALL_PREFIX="$(get_llvm_prefix)"
+		# Relative path to the clang library
+		# https://github.com/include-what-you-use/include-what-you-use/commit/e046d23571876e72719ef96a36ff0cb1cb2e64b6
+		-DIWYU_RESOURCE_DIR="../../../clang/${LLVM_SLOT}"
+	)
+	cmake_src_configure
+}
+
+src_test() {
+	"${EPYTHON}" run_iwyu_tests.py \
+				 -- "${BUILD_DIR}"/bin/${PN} \
+		|| die "Tests failed with $? (using ${EPYTHON})"
+}
diff --git a/dev-util/include-what-you-use/include-what-you-use-0.23.ebuild b/dev-util/include-what-you-use/include-what-you-use-0.23.ebuild
index 7c911d0e33dc..a4f3b24ccc2f 100644
--- a/dev-util/include-what-you-use/include-what-you-use-0.23.ebuild
+++ b/dev-util/include-what-you-use/include-what-you-use-0.23.ebuild
@@ -30,10 +30,6 @@ DEPEND="${RDEPEND}"
 
 REQUIRED_USE="${PYTHON_REQUIRED_USE}"
 
-llvm_check_deps() {
-	has_version "llvm-core/clang:${LLVM_SLOT}"
-}
-
 pkg_setup() {
 	llvm-r1_pkg_setup
 	python-single-r1_pkg_setup