summaryrefslogtreecommitdiff
path: root/dev-util
diff options
context:
space:
mode:
Diffstat (limited to 'dev-util')
-rw-r--r--dev-util/cppcheck/cppcheck-2.13.0.ebuild2
-rw-r--r--dev-util/diffoscope/Manifest1
-rw-r--r--dev-util/diffoscope/diffoscope-271.ebuild131
-rw-r--r--dev-util/librnp/librnp-0.17.1.ebuild85
-rw-r--r--dev-util/rbtools/Manifest1
-rw-r--r--dev-util/rbtools/files/rbtools-5.0-importlib-resources.patch14
-rw-r--r--dev-util/rbtools/rbtools-5.0.ebuild57
-rw-r--r--dev-util/spirv-llvm-translator/spirv-llvm-translator-15.0.0-r1.ebuild3
-rw-r--r--dev-util/spirv-llvm-translator/spirv-llvm-translator-16.0.0-r1.ebuild3
-rw-r--r--dev-util/spirv-llvm-translator/spirv-llvm-translator-17.0.0-r2.ebuild3
-rw-r--r--dev-util/spirv-llvm-translator/spirv-llvm-translator-18.1.0.ebuild3
-rw-r--r--dev-util/tree-sitter-cli/tree-sitter-cli-0.22.5.ebuild2
12 files changed, 218 insertions, 87 deletions
diff --git a/dev-util/cppcheck/cppcheck-2.13.0.ebuild b/dev-util/cppcheck/cppcheck-2.13.0.ebuild
index 06bbd7359a0d..a4298a4f2233 100644
--- a/dev-util/cppcheck/cppcheck-2.13.0.ebuild
+++ b/dev-util/cppcheck/cppcheck-2.13.0.ebuild
@@ -12,7 +12,7 @@ SRC_URI="https://github.com/danmar/cppcheck/archive/refs/tags/${PV}.tar.gz -> ${
LICENSE="GPL-3+"
SLOT="0"
-KEYWORDS="amd64 ~arm arm64 ~loong ~ppc64 ~riscv ~x86"
+KEYWORDS="amd64 ~arm arm64 ~loong ppc64 ~riscv ~x86"
IUSE="charts gui qt6 htmlreport pcre test threads"
REQUIRED_USE="
${PYTHON_REQUIRED_USE}
diff --git a/dev-util/diffoscope/Manifest b/dev-util/diffoscope/Manifest
index df3af377b897..335cf5fc2eed 100644
--- a/dev-util/diffoscope/Manifest
+++ b/dev-util/diffoscope/Manifest
@@ -1,2 +1,3 @@
DIST diffoscope-266.tar.bz2 3148610 BLAKE2B 28090b8a1e2315f9df43d254d3dbd4ed8f6d4ba4d259c764f53b84137ac0b3dc97b51df56ba595eee950c54974e9b6109c423392d198e277d520f11559ecd78e SHA512 2eb7cbd333b6559ba0f66647184f1747cac52cca6304a27eefe914329797469d5fb9519abe92386d3785f4f2c779f8f5dd95ecc8f54f8b08fd4fc94746bf273d
DIST diffoscope-268.tar.bz2 3151657 BLAKE2B 2133611135347a9babfb55972ef5d456cc274634facc07ea8dc2c214147507d223a6fd8cf24541c04fc19c3510c7548bdaa5549f5587c9d99de7b61e64bd2f7d SHA512 9a0f3c81e9beb171fdef8282ac3938a5534f894437f898ab1437cdeb30a12c7fb8a1a494479f46c41d65e78fe014b8c1e510a72d0673f3d0d769d71c4af12a5d
+DIST diffoscope-271.tar.bz2 3155727 BLAKE2B fa4ee93158cf41215d071aa3caa1956325fdbb1e4f1a9e392485117cb58b8142ac7f326cd650e72440a2512a08aa2c6a7d9c64a0fa8bf9768c9f0d97a45d872e SHA512 f5688d82313f54a9b9db88c406cdd67f13aeb65a8aa844fa41a944f6beaa0b2189175c891ddaf3b345492141472ce0366fd22691c2c89fd9a3d8c0b8d62f476c
diff --git a/dev-util/diffoscope/diffoscope-271.ebuild b/dev-util/diffoscope/diffoscope-271.ebuild
new file mode 100644
index 000000000000..f3680e18f668
--- /dev/null
+++ b/dev-util/diffoscope/diffoscope-271.ebuild
@@ -0,0 +1,131 @@
+# Copyright 2022-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11,12} )
+PYTHON_REQ_USE="ncurses"
+inherit distutils-r1
+
+DESCRIPTION="Will try to get to the bottom of what makes files or directories different"
+HOMEPAGE="https://diffoscope.org/ https://pypi.org/project/diffoscope/"
+# We could use pypi, but upstream provide distribution tarballs, so let's use those.
+# TODO: verify-sig
+SRC_URI="https://diffoscope.org/archive/${P}.tar.bz2"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ia64 ~ppc64 ~x86"
+IUSE="acl binutils bzip2 libcaca colord cpio +diff docx dtc e2fsprogs file
+find gettext gif gpg haskell hdf5 hex imagemagick iso java llvm lzma
+mono opendocument pascal pdf postscript R rpm sqlite squashfs
+ssh tar test tcpdump zip zlib zstd"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+ || (
+ dev-python/python-magic[${PYTHON_USEDEP}]
+ sys-apps/file[python,${PYTHON_USEDEP}]
+ )
+ dev-python/libarchive-c[${PYTHON_USEDEP}]
+ dev-python/distro[${PYTHON_USEDEP}]
+ dev-python/tlsh[${PYTHON_USEDEP}]
+ acl? ( sys-apps/acl )
+ binutils? ( sys-devel/binutils )
+ bzip2? ( app-arch/bzip2 )
+ libcaca? ( media-libs/libcaca )
+ colord? ( x11-misc/colord )
+ cpio? ( app-alternatives/cpio )
+ diff? ( sys-apps/diffutils )
+ docx? ( app-text/docx2txt )
+ dtc? ( sys-apps/dtc )
+ e2fsprogs? ( sys-fs/e2fsprogs )
+ file? ( sys-apps/file )
+ find? ( sys-apps/findutils )
+ gettext? ( sys-devel/gettext )
+ gif? ( media-libs/giflib )
+ gpg? ( app-crypt/gnupg )
+ haskell? ( dev-lang/ghc )
+ hdf5? ( sci-libs/hdf5 )
+ hex? ( app-editors/vim-core )
+ imagemagick? ( media-gfx/imagemagick )
+ iso? ( app-cdr/cdrtools )
+ java? ( virtual/jdk )
+ llvm? ( sys-devel/llvm )
+ lzma? ( app-arch/xz-utils )
+ mono? ( dev-lang/mono )
+ opendocument? ( app-text/odt2txt )
+ pascal? ( dev-lang/fpc )
+ pdf? (
+ app-text/pdftk
+ app-text/poppler
+ dev-python/pypdf[${PYTHON_USEDEP}]
+ )
+ postscript? ( app-text/ghostscript-gpl )
+ R? ( dev-lang/R )
+ rpm? ( app-arch/rpm )
+ sqlite? ( dev-db/sqlite:3 )
+ squashfs? ( sys-fs/squashfs-tools )
+ ssh? ( virtual/openssh )
+ tar? ( app-arch/tar )
+ tcpdump? ( net-analyzer/tcpdump )
+ zip? ( app-arch/unzip )
+ zlib? ( app-arch/gzip )
+ zstd? ( app-arch/zstd )
+"
+
+# pull in optional tools for tests:
+# img2txt: bug #797688
+# docx2txt: bug #797688
+BDEPEND="
+ test? (
+ app-arch/p7zip
+ app-text/docx2txt
+ app-text/html2text
+ media-libs/libcaca
+ virtual/imagemagick-tools[jpeg]
+ )
+"
+
+EPYTEST_DESELECT=(
+ # Test seems to use different tarball
+ tests/test_presenters.py::test_text_proper_indentation
+
+ # Needs triage
+ tests/comparators/test_binary.py::test_with_compare_details_and_tool_not_found
+ tests/comparators/test_rlib.py::test_item3_deflate_llvm_bitcode
+ tests/comparators/test_gif.py::test_has_visuals
+
+ # img2txt based failures, bug #797688
+ tests/comparators/test_ico_image.py::test_diff
+ tests/comparators/test_ico_image.py::test_diff_meta
+ tests/comparators/test_ico_image.py::test_diff_meta2
+ tests/comparators/test_ico_image.py::test_has_visuals
+ tests/comparators/test_jpeg_image.py::test_diff
+ tests/comparators/test_jpeg_image.py::test_compare_non_existing
+ tests/comparators/test_jpeg_image.py::test_diff_meta
+ tests/comparators/test_jpeg_image.py::test_has_visuals
+
+ # docx2txt based falures, bug #797688
+ tests/comparators/test_docx.py::test_diff
+
+ # Formatting
+ tests/test_source.py::test_code_is_black_clean
+
+ # Fails on ZFS
+ tests/test_main.py::test_non_unicode_filename
+
+ # Fails on (unreleased) LLVM 16 with minor difference
+ #tests/comparators/test_macho.py::test_llvm_diff
+ #tests/comparators/test_elf.py::test_libmix_differences
+
+ # Fails with perl-5.40
+ # https://salsa.debian.org/reproducible-builds/diffoscope/-/issues/377
+ tests/comparators/test_epub.py::test_differences
+ tests/comparators/test_zip.py::test_metadata
+ tests/comparators/test_zip.py::test_extra_fields
+ tests/comparators/test_zip.py::test_commented
+)
+
+distutils_enable_tests pytest
diff --git a/dev-util/librnp/librnp-0.17.1.ebuild b/dev-util/librnp/librnp-0.17.1.ebuild
deleted file mode 100644
index 30ef40bae3c2..000000000000
--- a/dev-util/librnp/librnp-0.17.1.ebuild
+++ /dev/null
@@ -1,85 +0,0 @@
-# Copyright 2022-2024 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-inherit cmake multiprocessing
-
-DESCRIPTION="High performance C++ OpenPGP library"
-HOMEPAGE="https://www.rnpgp.org/ https://github.com/rnpgp/rnp"
-SRC_URI="https://github.com/rnpgp/rnp/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
-
-LICENSE="Apache-2.0 BSD BSD-2"
-SLOT="0/0.16.1"
-KEYWORDS="~amd64 ~arm64 ~loong ~ppc64 ~x86"
-IUSE="+botan man test"
-
-RDEPEND="app-arch/bzip2
- dev-libs/json-c:=
- >=dev-libs/sexpp-0.8.7
- sys-libs/zlib
- botan? ( dev-libs/botan:= )
- !botan? ( >=dev-libs/openssl-1.1.1:= )"
-DEPEND="${RDEPEND}
- test? ( dev-cpp/gtest )"
-BDEPEND="man? ( dev-ruby/asciidoctor )"
-
-RESTRICT="!test? ( test )"
-S="${WORKDIR}/${P/*lib/}"
-
-src_configure() {
- local mycmakeargs=(
- -DBUILD_TESTING=$(usex test on off)
-
- -DCRYPTO_BACKEND=$(usex botan botan openssl)
-
- -DDOWNLOAD_GTEST=off
-
- -DENABLE_COVERAGE=off
- -DENABLE_DOC=$(usex man on off)
- -DENABLE_FUZZERS=off
- -DENABLE_SANITIZERS=off
-
- -DSYSTEM_LIBSEXPP=on
- )
-
- if use botan; then
- local mycmakeargs+=(
- -DENABLE_AEAD=on
- -DENABLE_BLOWFISH=on
- -DENABLE_BRAINPOOL=on
- -DENABLE_CAST5=on
- -DENABLE_IDEA=on
- -DENABLE_RIPEMD160=on
- -DENABLE_SM2=on
- -DENABLE_TWOFISH=on
- )
-
- # OpenSSL support is still not as complete as botan.
- # https://github.com/rnpgp/rnp/issues/1877 SM2,
- # https://github.com/openssl/openssl/issues/2046 TWOFISH (won't be implemented).
- else
- local mycmakeargs+=(
- -DENABLE_AEAD=on
- -DENABLE_BLOWFISH=on
- -DENABLE_BRAINPOOL=on
- -DENABLE_CAST5=on
- -DENABLE_IDEA=on
- -DENABLE_RIPEMD160=on
- -DENABLE_SM2=off
- -DENABLE_TWOFISH=off
- )
- fi
-
- cmake_src_configure
-}
-
-src_test() {
- cd "${BUILD_DIR}"/src/tests || die
- ctest -j$(makeopts_jobs) -R .* --output-on-failure || die
-}
-
-src_install() {
- cmake_src_install
- find "${D}" -name '*.a' -delete || die
-}
diff --git a/dev-util/rbtools/Manifest b/dev-util/rbtools/Manifest
index 58e5535b93b2..d508f2d39112 100644
--- a/dev-util/rbtools/Manifest
+++ b/dev-util/rbtools/Manifest
@@ -1 +1,2 @@
DIST rbtools-4.1.tar.gz 619541 BLAKE2B 9b1aeca4f139a0189affb873363dba8f6d13eb954d4872939c543f6d91c00b09b2452cc379d4d99450c05d3d44a1996e910ff512ba9849292a7b705ce01be654 SHA512 58aa58ce6c55d4d3be9f221c493c8a3c15537776ff4e28be1ea44c0441f1dd9877ac9145066fdceb90d392c75cf29ec80e7efd154b0a2f1893422b65a0189ea0
+DIST rbtools-5.0.tar.gz 649338 BLAKE2B c6a08004e7c8ba17936865e53b78e086ec74e8f5fee7ecc124750f3bf24b9b52ab8a26d1caa7010cdd2822463fcb27b8e5c5f757068924e22d3e59268166f7bf SHA512 7fbc5198fc89ee911a3cc487ead094d46213cfc4f85ab01cf22bd2a628559acdaaed138b430b08aa94ea25dec1179bf7c28349ac8226d632a6112ec83e2b57b7
diff --git a/dev-util/rbtools/files/rbtools-5.0-importlib-resources.patch b/dev-util/rbtools/files/rbtools-5.0-importlib-resources.patch
new file mode 100644
index 000000000000..fa23c587a77a
--- /dev/null
+++ b/dev-util/rbtools/files/rbtools-5.0-importlib-resources.patch
@@ -0,0 +1,14 @@
+--- a/rbtools/commands/setup_completion.py 2024-06-06 10:51:45.000000000 +0200
++++ b/rbtools/commands/setup_completion.py 2024-06-08 11:12:34.788309950 +0200
+@@ -6,7 +6,10 @@
+ import sys
+ from typing import Optional
+
+-import importlib_resources
++try:
++ import importlib.resources as importlib_resources
++except ImportError:
++ import importlib_resources
+
+ from rbtools.commands.base import BaseCommand, CommandError
+
diff --git a/dev-util/rbtools/rbtools-5.0.ebuild b/dev-util/rbtools/rbtools-5.0.ebuild
new file mode 100644
index 000000000000..e7d7f1088522
--- /dev/null
+++ b/dev-util/rbtools/rbtools-5.0.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11,12} )
+
+inherit distutils-r1
+
+DESCRIPTION="Command line tools for use with Review Board"
+HOMEPAGE="https://www.reviewboard.org/"
+SRC_URI="https://github.com/reviewboard/rbtools/archive/refs/tags/release-${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/rbtools-release-${PV}"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE=""
+
+RDEPEND="
+ >=dev-python/certifi-2023.5.7[${PYTHON_USEDEP}]
+ dev-python/colorama[${PYTHON_USEDEP}]
+ >=dev-python/housekeeping-1.1[${PYTHON_USEDEP}]
+ =dev-python/housekeeping-1*[${PYTHON_USEDEP}]
+ >=dev-python/packaging-21.3[${PYTHON_USEDEP}]
+ =dev-python/pydiffx-1.1*[${PYTHON_USEDEP}]
+ dev-python/texttable[${PYTHON_USEDEP}]
+ >=dev-python/typing-extensions-4.3.0[${PYTHON_USEDEP}]
+ dev-python/tqdm[${PYTHON_USEDEP}]
+ >=dev-python/importlib-metadata-5.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+ dev-python/setuptools[${PYTHON_USEDEP}]
+ test? (
+ >=dev-python/kgb-6.1[${PYTHON_USEDEP}]
+ dev-python/pytest-env[${PYTHON_USEDEP}]
+ dev-vcs/git
+ dev-vcs/mercurial
+ )
+"
+
+PATCHES=( "${FILESDIR}/${P}-importlib-resources.patch" )
+
+DOCS=( AUTHORS NEWS README.md )
+
+distutils_enable_tests pytest
+
+src_prepare() {
+ default
+
+ # Avoid tests requiring unpackaged test data
+ rm -f rbtools/clients/tests/test_scanning.py || die
+
+ # Avoid repository specific tests to avoid dependencies on them
+ rm -f rbtools/clients/tests/test_{cvs,git,mercurial,svn}.py || die
+}
diff --git a/dev-util/spirv-llvm-translator/spirv-llvm-translator-15.0.0-r1.ebuild b/dev-util/spirv-llvm-translator/spirv-llvm-translator-15.0.0-r1.ebuild
index bdefd6ed9703..29e6a6ab500f 100644
--- a/dev-util/spirv-llvm-translator/spirv-llvm-translator-15.0.0-r1.ebuild
+++ b/dev-util/spirv-llvm-translator/spirv-llvm-translator-15.0.0-r1.ebuild
@@ -40,6 +40,9 @@ PATCHES=( "${FILESDIR}"/${PN}-15.0.0-intel-capability.patch )
src_prepare() {
append-flags -fPIC
cmake_src_prepare
+
+ # https://github.com/KhronosGroup/SPIRV-LLVM-Translator/pull/2555
+ sed -i -e 's/%triple/x86_64-unknown-linux-gnu/' test/DebugInfo/X86/*.ll || die
}
src_configure() {
diff --git a/dev-util/spirv-llvm-translator/spirv-llvm-translator-16.0.0-r1.ebuild b/dev-util/spirv-llvm-translator/spirv-llvm-translator-16.0.0-r1.ebuild
index 194b82f52b5f..fb3e58b930a6 100644
--- a/dev-util/spirv-llvm-translator/spirv-llvm-translator-16.0.0-r1.ebuild
+++ b/dev-util/spirv-llvm-translator/spirv-llvm-translator-16.0.0-r1.ebuild
@@ -44,6 +44,9 @@ PATCHES=(
src_prepare() {
append-flags -fPIC
cmake_src_prepare
+
+ # https://github.com/KhronosGroup/SPIRV-LLVM-Translator/pull/2555
+ sed -i -e 's/%triple/x86_64-unknown-linux-gnu/' test/DebugInfo/X86/*.ll || die
}
src_configure() {
diff --git a/dev-util/spirv-llvm-translator/spirv-llvm-translator-17.0.0-r2.ebuild b/dev-util/spirv-llvm-translator/spirv-llvm-translator-17.0.0-r2.ebuild
index 966037d0d746..f88cc260c9b8 100644
--- a/dev-util/spirv-llvm-translator/spirv-llvm-translator-17.0.0-r2.ebuild
+++ b/dev-util/spirv-llvm-translator/spirv-llvm-translator-17.0.0-r2.ebuild
@@ -43,6 +43,9 @@ PATCHES=(
src_prepare() {
append-flags -fPIC
cmake_src_prepare
+
+ # https://github.com/KhronosGroup/SPIRV-LLVM-Translator/pull/2555
+ sed -i -e 's/%triple/x86_64-unknown-linux-gnu/' test/DebugInfo/X86/*.ll || die
}
src_configure() {
diff --git a/dev-util/spirv-llvm-translator/spirv-llvm-translator-18.1.0.ebuild b/dev-util/spirv-llvm-translator/spirv-llvm-translator-18.1.0.ebuild
index acf2b6f81bde..63f846f23177 100644
--- a/dev-util/spirv-llvm-translator/spirv-llvm-translator-18.1.0.ebuild
+++ b/dev-util/spirv-llvm-translator/spirv-llvm-translator-18.1.0.ebuild
@@ -41,6 +41,9 @@ PATCHES=(
src_prepare() {
append-flags -fPIC
cmake_src_prepare
+
+ # https://github.com/KhronosGroup/SPIRV-LLVM-Translator/pull/2555
+ sed -i -e 's/%triple/x86_64-unknown-linux-gnu/' test/DebugInfo/X86/*.ll || die
}
src_configure() {
diff --git a/dev-util/tree-sitter-cli/tree-sitter-cli-0.22.5.ebuild b/dev-util/tree-sitter-cli/tree-sitter-cli-0.22.5.ebuild
index 41b809340b75..2cde78e94590 100644
--- a/dev-util/tree-sitter-cli/tree-sitter-cli-0.22.5.ebuild
+++ b/dev-util/tree-sitter-cli/tree-sitter-cli-0.22.5.ebuild
@@ -21,7 +21,7 @@ LICENSE+="
Unicode-DFS-2016
"
SLOT="0"
-KEYWORDS="amd64 ~arm ~arm64 ~loong ppc ~ppc64 ~riscv ~s390 sparc x86"
+KEYWORDS="amd64 arm arm64 ~loong ppc ppc64 ~riscv ~s390 sparc x86"
# Test seems to require files (grammar definitions) that we don't have.
RESTRICT="test"
generated by cgit v1.3 (git 2.53.0) at 2026-10-14 19:09:09 +0000