4 files changed, 127 insertions, 3 deletions
diff --git a/dev-util/mesa_clc/Manifest b/dev-util/mesa_clc/Manifest
index aca5e38fd4c7..6c5a73e9a921 100644
--- a/dev-util/mesa_clc/Manifest
+++ b/dev-util/mesa_clc/Manifest
@@ -7,3 +7,4 @@ DIST mesa-25.2.8.tar.xz 43813260 BLAKE2B 953b87f36d8bffc1bc5a5eef3f14da8ec8735bc
 DIST mesa-25.3.0.tar.xz 43281808 BLAKE2B 54cd99f9a4f14bf070f5525a91a776f0b7042ce7c056bf8db388baa5c98e0065799cdc376c0c42205b08eff18f252b6e7be5987e44fb628b97a360a7e89c300f SHA512 46df9e5e27f9a36cf893a68ad4a465fcc6efe1bcb46ad8d4b015699ad1a11e582b8d41f4157326556af603fe454b2ff34ecc17a0c742b5fd9ce5f0097106fec5
 DIST mesa-25.3.1.tar.xz 43316044 BLAKE2B 1c2927a04eeac787a583a31167ae1d40cb839fc45fcd3c0bad0e0b3842694444bd3f950d106f692ceb47b9881c9d101be995bcf7385a4fb992c54a23d56ffd1e SHA512 7e2f7295f1f4df129935b60d75c890f6ae585ecc511f69f55a61826df5f2434ffdb4109c632af9842a986bf9beed430a0404d377e8335b71fa36682bd10533ba
 DIST mesa-25.3.2.tar.xz 43373712 BLAKE2B f584ce53e1062657d2776e872a8fc9fc83cd209e6a700b0b0e4aff3a6c72c184452dde05dd84bdffe7011a5aecd812c7e454591b55a3c3832d8dcaa0a3aaf59a SHA512 499cb0aa254b5a706fb6c2414c23b9d5d03d9397475f7ad16744b982303a2a2bf643ef7adc64870645ee4355b5f95695becd6caff7d7f7caf698e6269589aa13
+DIST mesa-25.3.3.tar.xz 43385312 BLAKE2B 1f380c2fbd7c267a68757fc0d32272daddc4c376a65afda7df4e7a24a9597558ba8e93678f7163499e38d724063eb4446820ac43983a390ac34b15870c83009b SHA512 232b39f5035f8a65c8f815c8b524e3570f229673a85cd3591fbab9136c80b4ab922dc959f51a9d0a11e91cc66f8cf7f30cd9b846bb9e1607e3a6c820d5c8045a
diff --git a/dev-util/mesa_clc/mesa_clc-25.2.8.ebuild b/dev-util/mesa_clc/mesa_clc-25.2.8.ebuild
index 2eb73c85c0de..c86979d990bf 100644
--- a/dev-util/mesa_clc/mesa_clc-25.2.8.ebuild
+++ b/dev-util/mesa_clc/mesa_clc-25.2.8.ebuild
@@ -3,7 +3,7 @@
 
 EAPI=8
 
-LLVM_COMPAT=( {18..20} )
+LLVM_COMPAT=( {18..21} )
 PYTHON_COMPAT=( python3_{10..14} )
 
 inherit llvm-r1 meson python-any-r1
diff --git a/dev-util/mesa_clc/mesa_clc-25.3.3.ebuild b/dev-util/mesa_clc/mesa_clc-25.3.3.ebuild
new file mode 100644
index 000000000000..746023621fa9
--- /dev/null
+++ b/dev-util/mesa_clc/mesa_clc-25.3.3.ebuild
@@ -0,0 +1,123 @@
+# Copyright 2023-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+LLVM_COMPAT=( {18..21} )
+PYTHON_COMPAT=( python3_{10..14} )
+
+inherit llvm-r1 meson python-any-r1
+
+MY_PV="${PV/_/-}"
+
+DESCRIPTION="mesa_clc tool used for building OpenCL C to SPIR-V"
+HOMEPAGE="https://mesa3d.org/"
+
+if [[ ${PV} == 9999 ]]; then
+	S="${WORKDIR}/mesa_clc-${MY_PV}"
+	EGIT_REPO_URI="https://gitlab.freedesktop.org/mesa/mesa.git"
+	inherit git-r3
+else
+	S="${WORKDIR}/mesa-${MY_PV}"
+	SRC_URI="https://archive.mesa3d.org/mesa-${MY_PV}.tar.xz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+
+VIDEO_CARDS="asahi panfrost"
+for card in ${VIDEO_CARDS}; do
+	IUSE_VIDEO_CARDS+=" video_cards_${card}"
+done
+IUSE="${IUSE_VIDEO_CARDS} debug"
+
+RDEPEND="
+	dev-util/spirv-tools
+	$(llvm_gen_dep '
+		dev-util/spirv-llvm-translator:${LLVM_SLOT}
+		llvm-core/clang:${LLVM_SLOT}=
+		=llvm-core/libclc-${LLVM_SLOT}*
+		llvm-core/llvm:${LLVM_SLOT}=
+	')
+"
+DEPEND="${RDEPEND}
+	dev-libs/expat
+	>=virtual/zlib-1.2.8:=
+	x11-libs/libdrm
+"
+BDEPEND="
+	${PYTHON_DEPS}
+	$(python_gen_any_dep "
+		>=dev-python/mako-0.8.0[\${PYTHON_USEDEP}]
+		dev-python/packaging[\${PYTHON_USEDEP}]
+		dev-python/pyyaml[\${PYTHON_USEDEP}]
+	")
+	virtual/pkgconfig
+"
+
+python_check_deps() {
+	python_has_version -b ">=dev-python/mako-0.8.0[${PYTHON_USEDEP}]" &&
+	python_has_version -b "dev-python/packaging[${PYTHON_USEDEP}]" &&
+	python_has_version -b "dev-python/pyyaml[${PYTHON_USEDEP}]" || return 1
+}
+
+pkg_setup() {
+	llvm-r1_pkg_setup
+	python-any-r1_pkg_setup
+}
+
+src_configure() {
+	tools_enable video_cards_asahi asahi
+	tools_enable video_cards_panfrost panfrost
+
+	tools_list() {
+		local tools="$(sort -u <<< "${1// /$'\n'}")"
+		echo "${tools//$'\n'/,}"
+	}
+
+	PKG_CONFIG_PATH="$(get_llvm_prefix)/$(get_libdir)/pkgconfig"
+
+	use debug && EMESON_BUILDTYPE=debug
+
+	local emesonargs=(
+		-Dllvm=enabled
+		-Dshared-llvm=enabled
+		-Dmesa-clc=enabled
+		-Dinstall-mesa-clc=true
+		-Dprecomp-compiler=enabled
+		-Dinstall-precomp-compiler=true
+		-Dtools=$(tools_list "${TOOLS[*]}")
+
+		-Dgallium-drivers=''
+		-Dvulkan-drivers=''
+
+		# Set platforms empty to avoid the default "auto" setting. If
+		# platforms is empty meson.build will add surfaceless.
+		-Dplatforms=''
+
+		-Dglx=disabled
+		-Dlibunwind=disabled
+		-Dzstd=disabled
+
+		-Db_ndebug=$(usex debug false true)
+	)
+
+	meson_src_configure
+}
+
+src_install() {
+	dobin "${BUILD_DIR}"/src/compiler/clc/mesa_clc
+	dobin "${BUILD_DIR}"/src/compiler/spirv/vtn_bindgen2
+	use video_cards_asahi && dobin "${BUILD_DIR}"/src/asahi/clc/asahi_clc
+	use video_cards_panfrost && dobin "${BUILD_DIR}"/src/panfrost/clc/panfrost_compile
+}
+
+# $1 - VIDEO_CARDS flag (check skipped for "--")
+# other args - names of tools to enable
+tools_enable() {
+	if [[ $1 == -- ]] || use $1; then
+		shift
+		TOOLS+=("$@")
+	fi
+}
diff --git a/dev-util/spirv-llvm-translator/spirv-llvm-translator-21.1.3.ebuild b/dev-util/spirv-llvm-translator/spirv-llvm-translator-21.1.3.ebuild
index 46b86ab069c3..a5a7d6e848b8 100644
--- a/dev-util/spirv-llvm-translator/spirv-llvm-translator-21.1.3.ebuild
+++ b/dev-util/spirv-llvm-translator/spirv-llvm-translator-21.1.3.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2025 Gentoo Authors
+# Copyright 1999-2026 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=8
@@ -16,7 +16,7 @@ S="${WORKDIR}/${MY_P}"
 
 LICENSE="UoI-NCSA"
 SLOT="$(ver_cut 1)"
-KEYWORDS="~amd64 ~arm ~arm64 ~loong ~riscv ~x86"
+KEYWORDS="amd64 ~arm ~arm64 ~loong ~riscv ~x86"
 IUSE="test"
 RESTRICT="!test? ( test )"