blob: 9876e19fbf510cb3e7017d9642d8e913a00acc51 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
|
# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit autotools flag-o-matic xdg-utils
DESCRIPTION="A free ASCII-Text Screen Editor for UNIX"
HOMEPAGE="https://sourceforge.net/projects/joe-editor/ https://github.com/joe-editor/joe"
SRC_URI="https://downloads.sourceforge.net/joe-editor/${P}.tar.gz"
LICENSE="GPL-1+ CC-BY-3.0"
SLOT="0"
KEYWORDS="~alpha amd64 arm arm64 ~mips ppc ppc64 ~sparc x86 ~x64-macos ~x64-solaris"
IUSE="xterm"
DEPEND=">=sys-libs/ncurses-5.2-r2:0="
RDEPEND="${DEPEND}
xterm? ( >=x11-terms/xterm-239 )"
PATCHES=(
"${FILESDIR}/${PN}-4.3-tinfo.patch"
"${FILESDIR}/${PN}-4.7-db.patch"
"${FILESDIR}/${P}-stdin.patch"
)
DOCS=( README.md NEWS.md docs/hacking.md docs/man.md )
src_prepare() {
default
# Enable xterm mouse support in the rc files
if use xterm; then
pushd "${S}"/rc &>/dev/null || die
local i
for i in *rc*.in; do
sed -e 's/^ -\(mouse\|joexterm\)/-\1/' -i "${i}" || die
done
popd &>/dev/null || die
fi
# for signal handling
append-cflags -D_GNU_SOURCE
eautoreconf
}
pkg_postinst() {
xdg_desktop_database_update
xdg_icon_cache_update
if use xterm; then
elog "To enable full xterm clipboard you need to set the allowWindowOps"
elog "resources to true. This is usually found in /etc/X11/app-defaults/XTerm"
elog "This is false by default due to potential security problems on some"
elog "architectures (see bug #91453)."
fi
}
pkg_postrm() {
xdg_desktop_database_update
xdg_icon_cache_update
}
|
