blob: 3ab282622c8aa9b9952c0feda2149ceae40a2f80 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
|
# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI="8"
PYTHON_COMPAT=( python3_{13..14} )
inherit autotools gnome2-utils python-single-r1 xdg
DESCRIPTION="Japanese Anthy engine for IBus"
HOMEPAGE="https://github.com/ibus/ibus/wiki"
SRC_URI="https://github.com/ibus/${PN}/archive/${PV}/${P}.tar.gz"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="amd64 ~ppc x86"
IUSE="nls"
REQUIRED_USE="${PYTHON_REQUIRED_USE}"
RDEPEND="
${PYTHON_DEPS}
app-i18n/anthy-unicode
dev-libs/glib:2
$(python_gen_cond_dep '
app-i18n/ibus[python(+),${PYTHON_USEDEP}]
dev-python/pygobject:3[${PYTHON_USEDEP}]
')
nls? ( virtual/libintl )
"
DEPEND="${RDEPEND}"
BDEPEND="
${PYTHON_DEPS}
sys-devel/gettext
virtual/pkgconfig
"
PATCHES=(
"${FILESDIR}"/${PN}-1.5.18-fix_pkgconfig.patch
)
src_prepare() {
default
python_fix_shebang data/era.py
eautoreconf
gnome2_environment_reset
}
src_configure() {
local myeconfargs=(
$(use_enable nls)
--enable-private-png
--with-layout=default
--with-python=${EPYTHON}
)
econf "${myeconfargs[@]}"
}
src_test() {
:
}
src_install() {
default
find "${ED}" -name '*.la' -delete || die
# py-compile launched by Makefile
# python_optimize
}
pkg_preinst() {
xdg_pkg_preinst
gnome2_schemas_savelist
}
pkg_postinst() {
xdg_pkg_postinst
gnome2_schemas_update
if ! has_version app-dicts/kasumi; then
elog "app-dicts/kasumi is not required but probably useful for you."
fi
}
pkg_postrm() {
xdg_pkg_postrm
gnome2_schemas_update
}
|
