blob: 82bf759782ac68ba222a4b80fb3bc4a57ef513e8 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
|
# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DESCRIPTION="A somewhat comprehensive collection of Chinese Linux man pages"
HOMEPAGE="https://github.com/man-pages-zh/manpages-zh"
MY_PN="manpages-zh"
MY_P="${MY_PN}-${PV}"
SRC_URI="https://github.com/man-pages-zh/${MY_PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
S="${WORKDIR}/${MY_P}"
LICENSE="FDL-1.2"
SLOT="0"
KEYWORDS="~alpha amd64 arm arm64 ~hppa ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 ~sparc x86"
RDEPEND="virtual/man"
src_configure() {
:
}
src_compile() {
:
}
src_install() {
local prune_manpages=(
# groups' zh_CN manpage is already provided by sys-apps/shadow
# to avoid file collision, we have to remove it
groups.1
# Avoid collisions with >=sys-process/procps-4.0.5
pgrep.1 pidof.1 free.1 pmap.1 ps.1 pwdx.1 slabtop.1
tload.1 sysctl.8 vmstat.8 uptime.1 w.1 watch.1 top.1
procps.3 procps_misc.3 procps_pids.3 sysctl.conf.5
# sys-process/procps-4.0.6
kill.1
)
local man
for man in "${prune_manpages[@]}" ; do
rm -fv src/man${man#*.}/${man} || die
done
doman -i18n=zh_CN src/man?/*.[1-9]*
dodoc README.md AUTHORS ChangeLog NEWS
}
|
