blob: 73d33e745bd154568afab788095483769592f169 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
|
# Copyright 2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
LLVM_COMPAT=({15..21})
RUST_MIN_VER="1.95"
inherit cargo desktop xdg
DESCRIPTION="Access your Wayland/X11 desktop from Monado/WiVRn/SteamVR"
HOMEPAGE="https://github.com/wlx-team/wayvr"
SRC_URI="
https://github.com/wlx-team/wayvr/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz
https://github.com/wlx-team/wayvr/releases/download/v${PV}/vendor.tar.xz -> ${P}-vendor.tar.xz
"
LICENSE="GPL-3"
# Dependent crate licenses
LICENSE+="
0BSD Apache-2.0 Apache-2.0-with-LLVM-exceptions BSD-2 BSD CC0-1.0
ISC MIT MPL-2.0 UoI-NCSA Unicode-3.0 Unlicense ZLIB
"
SLOT="0"
KEYWORDS="~amd64"
REQUIRED_USE="
|| ( openvr openxr )
|| ( wayland X )
wayland? ( pipewire )
"
IUSE="+openvr +openxr +wayland +X +pipewire +osc"
DEPEND="
dev-libs/openssl
media-libs/alsa-lib
media-libs/dav1d
media-libs/fontconfig
sys-apps/dbus
media-libs/freetype
X? (
x11-libs/libxcb
x11-libs/libxkbcommon[X]
x11-libs/libX11
x11-libs/libXext
x11-libs/libXrandr
)
openvr? (
=media-libs/openvr-1.23.8-r0
)
openxr? (
media-libs/openxr-loader[X?,wayland?]
)
pipewire? (
media-video/pipewire
)
wayland? (
x11-libs/libxkbcommon[wayland]
)
"
BDEPEND="
media-libs/shaderc
virtual/pkgconfig
"
RDEPEND="${DEPEND}"
src_unpack()
{
cargo_src_unpack
ln -s "${WORKDIR}/vendor/"* "${CARGO_HOME}/gentoo/"
sed -i "${ECARGO_HOME}/config.toml" -e '/source.crates-io/d' || die
sed -i "${ECARGO_HOME}/config.toml" -e '/replace-with = "gentoo"/d' || die
sed -i "${ECARGO_HOME}/config.toml" -e '/local-registry = "\/nonexistent"/d' || die
cat "${WORKDIR}/vendor/vendor-config.toml" >> "${ECARGO_HOME}/config.toml" || die
}
src_configure() {
local myfeatures=(
$(usev openvr)
$(usev openxr)
$(usev wayland)
$(usev X x11)
$(usev pipewire)
$(usev osc)
)
cargo_src_configure --no-default-features
}
src_install()
{
doicon --size 256 wayvr/wayvr.png
doicon --size scalable wayvr/wayvr.svg
domenu wayvr/wayvr.desktop
cargo_src_install --frozen --path wayvr
#FIXME: wayvrctl fails to install as it tries to use the same features as wayvr itself
#cargo_src_install --frozen --path wayvrctl
}
pkg_postinst()
{
xdg_pkg_postinst
}
pkg_postrm()
{
xdg_pkg_postrm
}
|
