blob: 896c63b6c66492c8411bcb2cae61f699203f5b79 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
|
# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
EGIT_BRANCH="5.2"
ECM_HANDBOOK="optional"
ECM_TEST="forceoptional"
QTMIN=6.11.2
VIRTUALDBUS_TEST="true"
inherit ecm kde.org optfeature xdg
DESCRIPTION="Personal finance manager based on KDE Frameworks"
HOMEPAGE="https://kmymoney.org/"
if [[ ${KDE_BUILD_TYPE} = release ]]; then
# SRC_URI="mirror://kde/stable/${PN}/${PV}/${P}.tar.xz"
SRC_URI="https://dev.gentoo.org/~asturm/distfiles/kde/${P}.tar.xz" # at a05ef0f9
KEYWORDS="amd64"
fi
LICENSE="GPL-2"
SLOT="0"
IUSE="activities addressbook calendar hbci holidays sql sqlcipher"
[[ ${KDE_BUILD_TYPE} = live ]] && IUSE+=" experimental"
REQUIRED_USE="sqlcipher? ( sql )"
COMMON_DEPEND="
dev-cpp/gpgmepp:=
dev-libs/qgpgme:=
>=app-office/libalkimia-8.2.1:=
dev-libs/gmp:0=[cxx(+)]
dev-libs/kdiagram:6
dev-libs/libgpg-error
dev-libs/libofx:=
>=dev-libs/qtkeychain-0.16.0:=
>=dev-qt/qtbase-${QTMIN}:6[dbus,gui,network,sql?,widgets,xml]
>=dev-qt/qtsvg-${QTMIN}:6
>=kde-frameworks/karchive-${KFMIN}:6
>=kde-frameworks/kcmutils-${KFMIN}:6
>=kde-frameworks/kcodecs-${KFMIN}:6
>=kde-frameworks/kcompletion-${KFMIN}:6
>=kde-frameworks/kconfig-${KFMIN}:6
>=kde-frameworks/kconfigwidgets-${KFMIN}:6
>=kde-frameworks/kcoreaddons-${KFMIN}:6
>=kde-frameworks/kcrash-${KFMIN}:6
>=kde-frameworks/ki18n-${KFMIN}:6
>=kde-frameworks/kio-${KFMIN}:6
>=kde-frameworks/kitemmodels-${KFMIN}:6
>=kde-frameworks/kitemviews-${KFMIN}:6
>=kde-frameworks/kjobwidgets-${KFMIN}:6
>=kde-frameworks/knotifications-${KFMIN}:6
>=kde-frameworks/kservice-${KFMIN}:6
>=kde-frameworks/ktextwidgets-${KFMIN}:6
>=kde-frameworks/kwidgetsaddons-${KFMIN}:6
>=kde-frameworks/kxmlgui-${KFMIN}:6
>=kde-frameworks/sonnet-${KFMIN}:6
activities? ( kde-plasma/plasma-activities:6= )
addressbook? (
kde-apps/akonadi:6=
kde-apps/kidentitymanagement:6=
>=kde-frameworks/kcontacts-${KFMIN}:6
)
calendar? ( dev-libs/libical:= )
hbci? (
>=dev-qt/qtdeclarative-${QTMIN}:6
>=net-libs/aqbanking-6.8.4
>=sys-libs/gwenhywfar-5.14.1:=[qt6]
)
holidays? ( >=kde-frameworks/kholidays-${KFMIN}:6 )
sql? ( >=dev-qt/qtbase-${QTMIN}:6[sqlite] )
sqlcipher? ( dev-db/sqlcipher )
"
DEPEND="${COMMON_DEPEND}
dev-libs/boost
"
RDEPEND="${COMMON_DEPEND}
!${CATEGORY}/${PN}:5
"
BDEPEND="virtual/pkgconfig"
pkg_setup() {
if [[ ${KDE_BUILD_TYPE} = live ]] && use experimental; then
ewarn "USE experimental set: Building unfinished features."
ewarn "This *will* chew up your data. You have been warned."
fi
}
src_prepare() {
ecm_src_prepare
sed -e "/find_program.*CCACHE_PROGRAM/s/^/# /" \
-e "/if.*CCACHE_PROGRAM/s/CCACHE_PROGRAM/0/" \
-i CMakeLists.txt || die # no, no no.
}
src_configure() {
local mycmakeargs=(
-DBUILD_WITH_QT6=ON # high level CMake fix
-DENABLE_WOOB=OFF # ported to Py3; not yet re-added in Gentoo
-DUSE_QT_DESIGNER=OFF
$(cmake_use_find_package activities PlasmaActivities)
$(cmake_use_find_package addressbook KF6Contacts)
$(cmake_use_find_package addressbook KPim6Akonadi)
-DENABLE_LIBICAL=$(usex calendar)
-DENABLE_KBANKING=$(usex hbci)
$(cmake_use_find_package holidays KF6Holidays)
-DENABLE_SQLSTORAGE=$(usex sql)
$(cmake_use_find_package sql Qt6Sql)
-DENABLE_SQLCIPHER=$(usex sqlcipher)
)
[[ ${KDE_BUILD_TYPE} = live ]] &&
mycmakeargs+=( -DENABLE_COSTCENTER=$(usex experimental) )
ecm_src_configure
}
src_test() {
# bug 652636; bug 673052: needs kmymoney installed to succeed
local myctestargs=(
-E "(reports-chart-test|qsqlcipher-test)"
)
ecm_src_test
}
pkg_postinst() {
xdg_pkg_postinst
if [[ -z "${REPLACING_VERSIONS}" ]]; then
optfeature "more options for online stock quote retrieval" dev-perl/Finance-Quote
fi
}
|
