app-shells/pokemon-colorscripts/pokemon-colorscripts-9999.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38

# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

PYTHON_COMPAT=( python3_{13..14} )

inherit git-r3 python-single-r1

DESCRIPTION="Pokemon unicode sprites for your terminal!"
HOMEPAGE="https://gitlab.com/phoneybadger/pokemon-colorscripts"
EGIT_REPO_URI="https://gitlab.com/phoneybadger/pokemon-colorscripts.git"

LICENSE="MIT"
SLOT="0"

REQUIRED_USE="${PYTHON_REQUIRED_USE}"

RDEPEND="${PYTHON_DEPS}"

src_prepare() {
	default

	sed -i \
	's#PROGRAM_DIR = os.path.dirname(PROGRAM)#PROGRAM_DIR = "/opt/pokemon-colorscripts/"#g' \
	pokemon-colorscripts.py || die "sed failed."
}

src_install() {
	insinto /opt/pokemon-colorscripts
	doins -r colorscripts
	doins pokemon.json

	python_scriptinto /opt/pokemon-colorscripts
	python_doscript pokemon-colorscripts.py

	dosym -r /opt/pokemon-colorscripts/pokemon-colorscripts.py /usr/bin/pokemon-colorscripts
}