blob: b15957a6c8f762c01aeba7884c20aef1d720d4fc (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
|
# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit cmake flag-o-matic
DESCRIPTION="Library for Bible reading software"
HOMEPAGE="https://www.crosswire.org/sword/"
SRC_URI="https://www.crosswire.org/ftpmirror/pub/${PN}/source/v${PV%.*}/${P}.tar.gz"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha amd64 arm arm64 ~hppa ~loong ~mips ppc ppc64 ~riscv ~s390 ~sparc x86"
IUSE="clucene curl icu test utils"
REQUIRED_USE="test? ( curl icu utils )"
RESTRICT="!test? ( test )"
RDEPEND="
app-arch/bzip2
app-arch/xz-utils
virtual/zlib:=
curl? ( net-misc/curl )
icu? ( dev-libs/icu:= )
clucene? ( dev-cpp/clucene:1 )
"
DEPEND="${RDEPEND}"
BDEPEND="virtual/pkgconfig"
PATCHES=(
"${FILESDIR}"/${PN}-1.9.0-cflags.patch
"${FILESDIR}"/${PN}-1.9.0-cmake4.patch
"${FILESDIR}"/${PN}-1.9.0-fix_glob_testfiles.patch
)
DOCS=( AUTHORS CODINGSTYLE ChangeLog README examples/ samples/ )
src_configure() {
# Fix test compilation with char16_t stream operators removed in C++20
use test && append-cxxflags -std=c++17
local mycmakeargs=(
# skip unnecessary tests, bug #954771
-DCMAKE_DISABLE_FIND_PACKAGE_cppcheck="ON"
-DCMAKE_SKIP_RPATH="ON"
# default is shared and static
-DLIBSWORD_LIBRARY_TYPE="Shared"
-DLIB_INSTALL_DIR="${EPREFIX}/usr/$(get_libdir)"
-DSYSCONF_INSTALL_DIR="${EPREFIX}/etc"
-DSWORD_BUILD_TESTS=$(usex test)
-DSWORD_BUILD_UTILS=$(usev !utils No)
-DSWORD_NO_CLUCENE=$(usev !clucene Yes)
-DWITH_CLUCENE=$(usex clucene)
-DSWORD_NO_CURL=$(usev !curl Yes)
-DWITH_CURL=$(usex curl)
-DSWORD_NO_ICU=$(usev !icu Yes)
-DWITH_ICU=$(usex icu)
-DWITH_ZLIB=1
)
cmake_src_configure
}
src_test() {
local -x LD_LIBRARY_PATH="${BUILD_DIR}"
cmake_src_test
}
|
