blob: b4af153fd76c43762d98d004467b3f82df19b29f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
|
# Copyright 2022-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
# These must be bumped together:
# dev-cpp/edencommon
# dev-cpp/fb303
# dev-cpp/fbthrift
# dev-cpp/fizz
# dev-cpp/folly
# dev-cpp/mvfst
# dev-cpp/wangle
# dev-util/watchman
inherit cmake flag-o-matic
DESCRIPTION="An implementation of the QUIC transport protocol"
HOMEPAGE="https://github.com/facebook/mvfst"
SRC_URI="https://github.com/facebook/mvfst/archive/refs/tags/v${PV}.tar.gz -> ${P}.gh.tar.gz"
LICENSE="MIT"
SLOT="0/${PV}"
KEYWORDS="amd64 ~arm64"
IUSE="test"
RESTRICT="!test? ( test )"
RDEPEND="
~dev-cpp/fizz-${PV}:=
~dev-cpp/folly-${PV}:=
dev-cpp/gflags:=
dev-cpp/glog:=[gflags]
dev-libs/double-conversion:=
dev-libs/libfmt:=
dev-libs/openssl:=
"
DEPEND="
${RDEPEND}
test? ( dev-cpp/gtest )
"
PATCHES=(
"${FILESDIR}"/${PN}-2025.04.14.00-boost-1.89.patch
)
src_configure() {
# -Wodr with IOBufBatchWriter, at least with -fno-semantic-interposition
filter-lto
local mycmakeargs=(
-DCMAKE_INSTALL_MODULE_DIR="$(get_libdir)/cmake/${PN}"
-DCMAKE_INSTALL_LIBDIR="$(get_libdir)"
-DBUILD_TESTS="$(usex test ON OFF)"
)
cmake_src_configure
}
src_test() {
if use arm64; then
# These tests segfault on arm64.
# https://github.com/facebook/mvfst/issues/363
CMAKE_SKIP_TESTS=(
QuicClientTransportIntegrationTest.ResetClient
QuicClientTransportIntegrationTest.TestStatelessResetToken
)
fi
cmake_src_test
}
|
