blob: 0b67722dce01d75d0c31e35cf16b9ea65026f002 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
|
# Copyright 1999-2025 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
JAVA_PKG_IUSE="doc source test"
JAVA_TESTING_FRAMEWORKS="junit-jupiter"
MAVEN_ID="com.github.jnr:jnr-ffi:2.2.17"
inherit java-pkg-2 java-pkg-simple junit5 toolchain-funcs
DESCRIPTION="A library for invoking native functions from java"
HOMEPAGE="https://github.com/jnr/jnr-ffi"
SRC_URI="https://github.com/jnr/${PN}/archive/${P}.tar.gz"
S="${WORKDIR}/${PN}-${P}"
LICENSE="Apache-2.0"
SLOT="0"
KEYWORDS="amd64 arm64 ppc64"
CP_DEPEND="
dev-java/asm:0
>=dev-java/jffi-1.3.13:0
dev-java/jnr-a64asm:2
dev-java/jnr-x86asm:1.0
"
DEPEND="
${CP_DEPEND}
>=virtual/jdk-1.8:*
test? ( dev-java/opentest4j:0 )
"
RDEPEND="
${CP_DEPEND}
>=virtual/jre-1.8:*
"
PATCHES=( "${FILESDIR}/jnr-ffi-2.2.17-r1-GetLoadedLibrariesTest.patch" )
JAVA_SRC_DIR="src/main/java"
JAVA_TEST_EXTRA_ARGS=( -Djava.library.path=build )
JAVA_TEST_GENTOO_CLASSPATH="junit-5 opentest4j"
JAVA_TEST_SRC_DIR="src/test/java"
src_prepare() {
default #780585
java-pkg-2_src_prepare
}
src_test() {
emake -f libtest/GNUmakefile CC="$(tc-getCC)"
junit5_src_test
}
|
