blob: 45422ee451aa62ad3f12b018e6fc2bb8e66a1f9a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
|
# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
WX_GTK_VER="3.2-gtk3"
PYTHON_COMPAT=( python3_{13..14} )
inherit cmake flag-o-matic python-single-r1 toolchain-funcs virtualx wxwidgets
DESCRIPTION="GNU Data Language"
HOMEPAGE="https://github.com/gnudatalanguage/gdl"
SRC_URI="https://github.com/gnudatalanguage/${PN}/releases/download/v${PV}/${PN}-v${PV}.tar.gz -> ${P}.tar.gz"
S="${WORKDIR}/${PN}-v${PV}"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="
+eigen fftw glpk graphicsmagick gshhs hdf hdf5 +imagemagick netcdf
openmp png proj postscript python shapelib tiff udunits wxwidgets
"
REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
RDEPEND="
dev-cpp/antlr-cpp:2=
dev-libs/expat
media-libs/libpng:=
net-libs/libtirpc:=
sci-libs/gsl:=
sci-libs/plplot:=[X,cxx,dynamic,latex,wxwidgets?]
sys-libs/ncurses:=
sys-libs/readline:=
virtual/zlib:=
x11-libs/libX11
eigen? ( dev-cpp/eigen:= )
fftw? ( sci-libs/fftw:3.0= )
glpk? ( sci-mathematics/glpk:= )
gshhs? (
sci-geosciences/gshhs-data
sci-geosciences/gshhs:=
)
hdf? ( sci-libs/hdf:= )
hdf5? ( sci-libs/hdf5:= )
imagemagick? (
!graphicsmagick? ( media-gfx/imagemagick:=[cxx] )
graphicsmagick? ( media-gfx/graphicsmagick:=[cxx] )
)
netcdf? ( sci-libs/netcdf:= )
proj? ( sci-libs/proj:= )
postscript? ( dev-libs/pslib )
python? (
${PYTHON_DEPS}
$(python_gen_cond_dep '
dev-python/numpy[${PYTHON_USEDEP}]
')
)
shapelib? ( sci-libs/shapelib:= )
tiff? (
media-libs/tiff:=
sci-libs/libgeotiff:=
)
udunits? ( sci-libs/udunits )
wxwidgets? ( x11-libs/wxGTK:${WX_GTK_VER}=[X] )
"
DEPEND="${RDEPEND}
"
BDEPEND="
virtual/pkgconfig
"
PATCHES=(
"${FILESDIR}"/${PN}-1.0.4-cmake.patch
"${FILESDIR}"/${PN}-1.0.4-r3-musl.patch
)
DOCS=( AUTHORS HACKING NEWS PYTHON.txt README README.md )
pkg_pretend() {
[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
}
pkg_setup() {
[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
use python && python-single-r1_pkg_setup
}
src_prepare() {
use hdf5 && has_version sci-libs/hdf5[mpi] && export CXX=mpicxx
# remove bundled antlr
rm -r src/antlr || die
# gentoo: avoid install files in datadir directory
# and manually install them in src_install
sed -e '/AUTHORS/d' -i CMakeLists.txt || die
cmake_src_prepare
}
src_configure() {
use wxwidgets && setup-wxwidgets unicode
# -Werror=strict-aliasing
# https://bugs.gentoo.org/930966
# https://github.com/gnudatalanguage/gdl/issues/1852
#
# Do not trust with LTO either.
append-flags -fno-strict-aliasing
filter-lto
# MPI is still very buggy
# x11=off does not compile
local mycmakeargs=(
-DMPI=OFF
-DREADLINE=ON
-DX11=ON
-DEXPAT=ON
-DPNGLIB=ON
-DEIGEN3=$(usex eigen)
-DFFTW=$(usex fftw)
-DGRIB=OFF
-DGLPK=$(usex glpk)
-DHDF=$(usex hdf)
-DHDF5=$(usex hdf5)
-DLIBPROJ=$(usex proj)
-DNETCDF=$(usex netcdf)
-DOPENMP=$(usex openmp)
-DPNGLIB=$(usex png)
-DUDUNITS2=$(usex udunits)
-DWXWIDGETS=$(usex wxwidgets)
-DGRAPHICSMAGICK=$(usex imagemagick $(usex graphicsmagick))
-DMAGICK=$(usex imagemagick $(usex !graphicsmagick))
-DTIFF=$(usex tiff)
-DGEOTIFF=$(usex tiff)
-DPYTHON_MODULE=$(usex python)
-DPYTHON=$(usex python)
-DSHAPELIB=$(usex shapelib)
-DQHULL=OFF
)
if use python; then
# automatically selection ignores EPYTHON
mycmakeargs+=(
-DPYTHONVERSION="${EPYTHON#python}"
)
fi
cmake_src_configure
}
src_test() {
PLPLOT_DRV_DIR=src/plplotdriver virtx cmake_src_test
}
src_install() {
cmake_src_install
newenvd - 50gdl <<-_EOF_
GDL_PATH="+${EPREFIX}/usr/share/gnudatalanguage"
_EOF_
}
|
