blob: e3b8899963fcc3e8a35819d5a089bec9eb2840e8 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
|
# Copyright 2021-2025 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit cmake
DESCRIPTION="Library for parsing, formatting, and validating international phone numbers"
HOMEPAGE="https://github.com/google/libphonenumber"
SRC_URI="https://github.com/google/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
CMAKE_USE_DIR="${WORKDIR}"/${P}/cpp
LICENSE="Apache-2.0"
SLOT="0"
KEYWORDS="amd64 arm64 ~ppc64 x86"
IUSE="test"
RESTRICT="!test? ( test )"
DEPEND="
dev-cpp/abseil-cpp:=
dev-libs/boost:=
dev-libs/icu:=
dev-libs/protobuf:=
"
RDEPEND="${DEPEND}"
BDEPEND="
virtual/pkgconfig
test? ( dev-cpp/gtest )
"
PATCHES=(
# it is either this, or disable BUILD_GEOCODER
# https://github.com/google/libphonenumber/pull/2556
"${FILESDIR}"/${PN}-8.13.47-cmake.patch
# bug #923946
"${FILESDIR}"/${PN}-8.13.47-protobuf-link-abseil.patch
# bug #889910
"${FILESDIR}"/${PN}-8.13.47-werror.patch
# bug 963681
"${FILESDIR}"/${PN}-8.13.47-boost-1.89.patch
)
src_prepare() {
# https://github.com/google/libphonenumber/pull/2860#issuecomment-1402766427
touch "${CMAKE_USE_DIR}"/src/phonenumbers/test_metadata.h || die
cmake_src_prepare
}
src_configure() {
local mycmakeargs=(
-DBUILD_STATIC_LIB=OFF
-DBUILD_TESTING=$(usex test)
-DREGENERATE_METADATA=OFF # avoid JRE dependency
)
cmake_src_configure
}
src_test() {
"${BUILD_DIR}"/libphonenumber_test || die
}
|
