blob: 6ab5fbf1ba52e83ca71abb4ca520c2a21cf90822 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
|
# Copyright 2024-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit cmake
DESCRIPTION="Cross platform native file dialog library with C and C++ bindings"
HOMEPAGE="https://github.com/btzy/nativefiledialog-extended/"
SRC_URI="
https://github.com/btzy/nativefiledialog-extended/archive/refs/tags/v${PV}.tar.gz
-> ${P}.tar.gz
"
LICENSE="ZLIB"
SLOT="0/$(ver_cut 1)"
KEYWORDS="~amd64 ~x86"
IUSE="X +desktop-portal wayland"
DEPEND="
desktop-portal? ( sys-apps/dbus )
!desktop-portal? (
dev-libs/glib:2
x11-libs/gtk+:3[X=,wayland=]
)
"
RDEPEND="
${DEPEND}
desktop-portal? ( sys-apps/xdg-desktop-portal )
"
PATCHES=(
"${FILESDIR}"/${PN}-1.2.1-libdir.patch
)
src_configure() {
local mycmakeargs=(
# tests are non-automated examples that open interactive dialogs
-DNFD_BUILD_TESTS=no
-DNFD_PORTAL="$(usex desktop-portal)"
)
cmake_src_configure
}
|
