blob: cf1faac20960b907d8b44034d2f0916e45c8f677 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
|
# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DISTUTILS_USE_PEP517=setuptools
PYPI_NO_NORMALIZE=1
PYTHON_COMPAT=( python3_{13..14} )
inherit distutils-r1 pypi
DESCRIPTION="This is a pytest plugin to help you test projects that use Trio"
HOMEPAGE="
https://github.com/python-trio/pytest-trio
https://pypi.org/project/pytest-trio/
"
LICENSE="|| ( MIT Apache-2.0 )"
SLOT="0"
KEYWORDS="amd64 arm arm64 ~loong ~mips ppc ppc64 ~riscv ~s390 ~sparc x86"
RDEPEND="
>=dev-python/outcome-1.1.0[${PYTHON_USEDEP}]
>=dev-python/pytest-7.2.0[${PYTHON_USEDEP}]
>=dev-python/trio-0.22.0[${PYTHON_USEDEP}]
"
EPYTEST_PLUGINS=( "${PN}" hypothesis )
EPYTEST_PLUGIN_LOAD_VIA_ENV=1
distutils_enable_tests pytest
distutils_enable_sphinx docs/source \
dev-python/attrs \
dev-python/sphinx-rtd-theme \
dev-python/sphinxcontrib-trio
python_prepare_all() {
local PATCHES=(
# https://github.com/python-trio/pytest-trio/pull/135
"${FILESDIR}/${P}-test.patch"
)
# Defining 'pytest_plugins' in a non-top-level conftest is no longer supported:
mv pytest_trio/_tests/conftest.py conftest.py || die
distutils-r1_python_prepare_all
}
|
