blob: 01d2191addbc53ac06f7422b84879eb1b08fc510 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
|
# Copyright 1999-2025 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit edo
DESCRIPTION="Claude Code - an agentic coding tool by Anthropic"
HOMEPAGE="https://www.anthropic.com/claude-code"
SRC_URI="https://registry.npmjs.org/@anthropic-ai/claude-code/-/claude-code-${PV}.tgz"
S="${WORKDIR}"
# NOTE(JayF): claude-code is only usable via paid subscription and has a
# clickthrough EULA-type license. Please see $HOMEPAGE for
# full details.
LICENSE="all-rights-reserved"
SLOT="0"
KEYWORDS="~amd64"
QA_PREBUILT="usr/lib64/node_modules/@anthropic-ai/claude-code/vendor/*"
RESTRICT="strip"
RDEPEND="
>=net-libs/nodejs-18
sys-apps/ripgrep
"
BDEPEND=">=net-libs/nodejs-18[npm]"
src_unpack() {
# npm installs the tarball directly
:
}
src_compile() {
# Skip, nothing to compile here.
:
}
src_install() {
local -a my_npm_opts=(
--audit false
--color false
--foreground-scripts
--global
--offline
--omit dev
--prefix "${ED}/usr"
--progress false
--verbose
)
edo npm "${my_npm_opts[@]}" install "${DISTDIR}/${P}.tgz"
rm -r "${ED}/usr/lib64/node_modules/@anthropic-ai/claude-code/vendor/ripgrep" || die
insinto /etc/claude-code
doins "${FILESDIR}/policies.json"
}
|
