blob: d4791bd103c13bbc67a5a12ff6bedf6d10e97629 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
|
# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
# Please bump the following packages together:
# dev-util/lttng-modules
# dev-util/lttng-tools
# dev-util/lttng-ust
PYTHON_COMPAT=( python3_{13..14} )
inherit autotools flag-o-matic python-any-r1 verify-sig
MY_P="${P/_rc/-rc}"
MY_SLOT="$(ver_cut 1-2)"
DESCRIPTION="Linux Trace Toolkit - UST library"
HOMEPAGE="https://lttng.org"
SRC_URI="
https://lttng.org/files/${PN}/${MY_P}.tar.bz2
verify-sig? ( https://lttng.org/files/${PN}/${MY_P}.tar.bz2.asc )
"
S="${WORKDIR}"/${MY_P}
LICENSE="GPL-2"
SLOT="0/${MY_SLOT}"
KEYWORDS="~alpha amd64 arm arm64 ~hppa ~loong ~mips ppc ppc64 ~riscv ~sparc x86"
IUSE="examples numa test"
RESTRICT="!test? ( test )"
DEPEND="
>=dev-libs/userspace-rcu-0.12:=
numa? ( sys-process/numactl )
"
RDEPEND="${DEPEND}"
BDEPEND="
${PYTHON_DEPS}
virtual/pkgconfig
test? ( dev-lang/perl )
verify-sig? ( sec-keys/openpgp-keys-mathieudesnoyers )
"
VERIFY_SIG_OPENPGP_KEY_PATH=/usr/share/openpgp-keys/mathieudesnoyers.asc
QA_CONFIG_IMPL_DECL_SKIP=(
pthread_get_name_np # different from pthread_getname_*, not on linux
pthread_set_name_np # different from pthread_setname_*, not on linux
)
src_prepare() {
default
# bug #944378
eautoreconf
}
src_configure() {
# bug #880357
strip-flags
local myeconfargs=(
$(use_enable examples)
$(use_enable numa)
)
econf "${myeconfargs[@]}"
}
src_install() {
default
find "${ED}" -type f -name '*.la' -delete || die
}
|
