blob: 13ac14e859a01c6ff5c599aeab9d2f698c53c57f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
|
# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit cmake xdg
HASH_CED="28f46c18c60b851773b0ff61f3ce416fb09adcf3"
HASH_PERFORMOUS="712c16daba6a6361a2feb1fdfd61b4fcdc581c8e"
DESCRIPTION="SingStar GPL clone"
HOMEPAGE="https://performous.org/"
SRC_URI="
https://github.com/performous/performous/archive/${HASH_PERFORMOUS}.tar.gz
-> ${P}.tar.gz
https://github.com/performous/compact_enc_det/archive/${HASH_CED}.tar.gz
-> ${PN}-ced-${HASH_CED}.tar.gz
songs? (
https://downloads.sourceforge.net/project/performous/ultrastar-songs-jc/1/ultrastar-songs-jc-1.zip
https://downloads.sourceforge.net/project/performous/ultrastar-songs-libre/3/ultrastar-songs-libre-3.zip
https://downloads.sourceforge.net/project/performous/ultrastar-songs-restricted/3/ultrastar-songs-restricted-3.zip
https://downloads.sourceforge.net/project/performous/ultrastar-songs-shearer/1/ultrastar-songs-shearer-1.zip
)
"
S="${WORKDIR}/${PN}-${HASH_PERFORMOUS}"
LICENSE="
GPL-2
Apache-2.0 OFL-1.1
songs? ( CC-BY-NC-SA-2.5 CC-BY-NC-ND-2.5 )
"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="midi songs test webcam"
RESTRICT="!test? ( test )"
RDEPEND="
dev-cpp/libxmlpp:5.0
dev-libs/boost:=[nls]
dev-libs/glib:2
dev-libs/icu:=
dev-libs/libfmt:=
gnome-base/librsvg:2
media-libs/aubio:=[blas,fftw]
media-libs/fontconfig:1.0
media-libs/glm
media-libs/libepoxy
media-libs/libjpeg-turbo:=
media-libs/libpng:=
media-libs/libsdl2[joystick,opengl,video]
media-libs/libwebp:=
media-libs/portaudio[cxx]
media-video/ffmpeg:=
virtual/zlib:=
virtual/libintl
x11-libs/cairo
x11-libs/pango
midi? ( media-libs/portmidi )
webcam? ( media-libs/opencv:= )
"
DEPEND="
${RDEPEND}
dev-cpp/nlohmann_json
dev-libs/spdlog
test? ( dev-cpp/gtest )
"
BDEPEND="
sys-apps/help2man
sys-devel/gettext
virtual/pkgconfig
songs? ( app-arch/unzip )
"
PATCHES=(
# avoid compressed manpages (gzip)
"${FILESDIR}"/${PN}-1.3.1-uncompressed_docs.patch
# use cblas implementation instead of restricting to openblas
"${FILESDIR}"/${PN}-1.3.1-cblas.patch
"${FILESDIR}"/${PN}-1.3.1-no_werror.patch
# PR pending https://github.com/performous/performous/pull/1105.patch
"${FILESDIR}"/${PN}-1.3.1-boost_1.89.patch
)
src_configure() {
local mycmakeargs=(
-DPERFORMOUS_VERSION=${PV}
-DSHARE_INSTALL="${EPREFIX}"/usr/share/${PN}
# it needs ON, not yes or something else
-DBUILD_TESTS=$(usex test ON OFF)
-DENABLE_MIDI=$(usex midi)
-DENABLE_TOOLS=ON # no dep
-DENABLE_WEBCAM=$(usex webcam)
# avoid 3rd party libs
-DSELF_BUILT_AUBIO=NEVER
-DSELF_BUILT_JSON=NEVER
-DSELF_BUILT_SPDLOG=NEVER
# compact_enc_det is not in tree
-DSELF_BUILT_CED=ALWAYS
-DFETCHCONTENT_SOURCE_DIR_CED-SRC:PATH="${WORKDIR}/compact_enc_det-${HASH_CED}"
# webserver needs unpackaged cpprestsdk which is not recommended for
# use by its upstream (dead), may consider adding only if requested
-DENABLE_WEBSERVER=no
)
cmake_src_configure
}
src_test() {
# avoid overflow failures
cmake_src_test -j1
}
src_install() {
local DOCS=( README.md docs/{Authors,instruments}.txt )
cmake_src_install
insinto /usr/share/${PN}
use songs && doins -r "${WORKDIR}"/songs
}
|
