blob: 0c3f9dbd93d1a693990e6fffe2160e4da8fd3a64 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
|
# Copyright 2023-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
LUA_COMPAT=( lua5-{1,3,4} luajit )
inherit lua-single cmake fcaps toolchain-funcs flag-o-matic
DESCRIPTION="A dynamic tiling Wayland compositor that doesn't sacrifice on its looks"
HOMEPAGE="https://github.com/hyprwm/Hyprland"
if [[ "${PV}" = *9999 ]]; then
inherit git-r3
EGIT_REPO_URI="https://github.com/hyprwm/${PN^}.git"
else
SRC_URI="https://github.com/hyprwm/${PN^}/releases/download/v${PV}/source-v${PV}.tar.gz -> ${P}.gh.tar.gz"
S="${WORKDIR}/${PN}-source"
KEYWORDS="~amd64"
fi
LICENSE="BSD"
SLOT="0/$(ver_cut 1-3)"
IUSE="+guiutils hyprpm systemd uwsm X +dbus-session rtkit"
REQUIRED_USE="${LUA_REQUIRED_USE}"
# Minimum required gcc and clang versions.
_MIN_GCC_VER=16
_MIN_CLANG_VER=19
# hyprpm (hyprland plugin manager) requires the dependencies at runtime
# so that it can clone, compile and install plugins.
HYPRPM_RDEPEND="
app-alternatives/ninja
>=dev-build/cmake-3.30
dev-vcs/git
virtual/pkgconfig
"
RDEPEND="
hyprpm? ( ${HYPRPM_RDEPEND} )
dev-cpp/muParser:=
rtkit? ( >=dev-cpp/sdbus-c++-2.0.0:= )
dev-cpp/tomlplusplus
dev-libs/glib:2
>=dev-libs/hyprlang-0.6.7:=
dev-libs/libei:=
>=dev-libs/libinput-1.29:=
>=dev-libs/hyprgraphics-0.5.1:=
dev-libs/re2:=
>=dev-libs/udis86-1.7.2
>=dev-libs/wayland-1.22.91
dev-util/glslang:=
>=gui-libs/aquamarine-0.15.0:=
>=gui-libs/hyprcursor-0.1.9:=
>=gui-libs/hyprutils-0.14.0:=
>=gui-libs/hyprwire-0.2.1:=
media-libs/lcms:=
media-libs/libcanberra:=
media-libs/libglvnd
media-libs/mesa
sys-apps/util-linux
x11-libs/cairo
x11-libs/libdrm
>=x11-libs/libxkbcommon-1.11.0
x11-libs/pango
x11-libs/pixman
x11-libs/libXcursor
guiutils? ( gui-libs/hyprland-guiutils:= )
X? (
x11-libs/libxcb:0=
x11-base/xwayland
x11-libs/xcb-util-errors
x11-libs/xcb-util-wm
)
dbus-session? ( sys-apps/dbus )
"
# dev-cpp/glaze should be only needed with hyprpm, but is needed by other
# headers.
DEPEND="
${RDEPEND}
${LUA_DEPS}
>=dev-cpp/glaze-7.0.0:=
>=dev-libs/hyprland-protocols-0.6.4
>=dev-libs/wayland-protocols-1.49
"
BDEPEND="
|| ( >=sys-devel/gcc-${_MIN_GCC_VER}:* >=llvm-core/clang-${_MIN_CLANG_VER}:* )
app-misc/jq
dev-build/cmake
>=dev-util/hyprwayland-scanner-0.4.5
virtual/pkgconfig
"
FILECAPS=(
cap_sys_nice usr/bin/Hyprland
)
pkg_setup() {
lua-single_pkg_setup
[[ ${MERGE_TYPE} == binary ]] && return
if tc-is-gcc && ver_test $(gcc-version) -lt ${_MIN_GCC_VER} ; then
eerror "Compiler is sys-devel/gcc-$(gcc-version), requires >=sys-devel/gcc-${_MIN_GCC_VER}."
die "Active compiler is too old for this package."
elif tc-is-clang && ver_test $(clang-version) -lt ${_MIN_CLANG_VER} ; then
eerror "Compiler is llvm-core/clang-$(clang-version), requires >=llvm-core/clang-${_MIN_CLANG_VER}."
die "Active compiler is too old for this package."
fi
}
src_prepare() {
if use hyprpm; then
PATCHES+=("${FILESDIR}/hyprland-0.56.0-hyprpm-set-lua.patch")
fi
if use dbus-session; then
sed -i \
"s|^Exec=|Exec=/usr/libexec/hyprland-dbus-run-session-if-needed |" \
example/hyprland.desktop.in || die
fi
cmake_src_prepare
}
src_configure() {
# Pass Gentoo lua-single pkg-config/CFLAGS information to hyprpm, so that
# runtime hyprpm update/add can build headers and plugins against the selected ELUA.
append-cxxflags \
"-DHYPRPM_GENTOO_LUA_PCFILE=\\\"/usr/$(get_libdir)/pkgconfig/${ELUA}.pc\\\"" \
"-DHYPRPM_EXTRA_CFLAGS=\\\"$(lua_get_CFLAGS)\\\"" \
"-DHYPRPM_EXTRA_CXXFLAGS=\\\"$(lua_get_CFLAGS)\\\""
local mycmakeargs=(
"-DBUILD_TESTING=OFF" # if enabled, creates a file inside /lib
# causing an error with multilib
-DNO_HYPRPM="$(usex !hyprpm)"
-DNO_RTKIT="$(usex !rtkit)"
-DNO_SYSTEMD="$(usex !systemd)"
-DNO_UWSM="$(usex !uwsm)"
-DNO_XWAYLAND="$(usex !X)"
)
cmake_src_configure
}
src_install() {
cmake_src_install
if use dbus-session; then
exeinto /usr/libexec
doexe "${FILESDIR}/hyprland-dbus-run-session-if-needed"
fi
}
|
