blob: 24c26841ad93cee30317653c0deb18a40cbe3197 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
|
# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
CARGO_OPTIONAL=1
CRATES="
"
RUST_MIN_VER="1.87.0"
ECM_HANDBOOK="forceoptional"
KFMIN=6.30.0
QTMIN=6.11.2
inherit cargo ecm flag-o-matic plasma.kde.org optfeature xdg
DESCRIPTION="Extra Plasma applets and engines"
if [[ ${KDE_BUILD_TYPE} == release ]] && [[ ${PKGBUMPING} != ${PVR} ]]; then
CRATES_PV=${PV}
if [[ ${KDE_ORG_UNRELEASED} && ${PV} == *.*.0 ]] ; then
# For unreleased versions (only .0), the last tag will (typically) be x.y.91.
# Just reuse a beta/rc crate tarball for that.
CRATES_PV=$(ver_cut 1).$((($(ver_cut 2) - 1))).91
fi
SRC_URI+=" https://github.com/gentoo-crate-dist/${PN}/releases/download/v${CRATES_PV}/${PN}-${CRATES_PV}-crates.tar.xz"
fi
LICENSE="GPL-2 LGPL-2"
# Dependent crate licenses
LICENSE+=" GPL-3 MIT Unicode-3.0 ZLIB"
SLOT="6"
KEYWORDS="~amd64 ~arm64"
IUSE="+alternate-calendar led share webengine"
RESTRICT="test" # bug 727846, +missing selenium-webdriver-at-spi
DEPEND="
>=dev-qt/qtbase-${QTMIN}:6[dbus,gui,network,widgets]
>=dev-qt/qtdeclarative-${QTMIN}:6
>=kde-frameworks/kcmutils-${KFMIN}:6
>=kde-frameworks/kconfig-${KFMIN}:6
>=kde-frameworks/kconfigwidgets-${KFMIN}:6
>=kde-frameworks/kcoreaddons-${KFMIN}:6
>=kde-frameworks/kdeclarative-${KFMIN}:6
>=kde-frameworks/kglobalaccel-${KFMIN}:6
>=kde-frameworks/kguiaddons-${KFMIN}:6
>=kde-frameworks/kholidays-${KFMIN}:6
>=kde-frameworks/ki18n-${KFMIN}:6
>=kde-frameworks/kio-${KFMIN}:6
>=kde-frameworks/kjobwidgets-${KFMIN}:6
>=kde-frameworks/knewstuff-${KFMIN}:6
>=kde-frameworks/knotifications-${KFMIN}:6
>=kde-frameworks/kpackage-${KFMIN}:6
>=kde-frameworks/krunner-${KFMIN}:6
>=kde-frameworks/kservice-${KFMIN}:6
>=kde-frameworks/ksvg-${KFMIN}:6
>=kde-frameworks/kunitconversion-${KFMIN}:6
>=kde-frameworks/kwidgetsaddons-${KFMIN}:6
>=kde-frameworks/kxmlgui-${KFMIN}:6
>=kde-frameworks/sonnet-${KFMIN}:6
>=kde-plasma/libplasma-${KDE_CATV}:6=
alternate-calendar? ( dev-libs/icu:= )
led? (
>=kde-frameworks/kauth-${KFMIN}:6
>=kde-frameworks/kdbusaddons-${KFMIN}:6
)
share? ( >=kde-frameworks/purpose-${KFMIN}:6 )
webengine? ( >=dev-qt/qtwebengine-${QTMIN}:6 )
"
RDEPEND="${DEPEND}
!<kde-plasma/plasma-workspace-6.4.80
dev-libs/kirigami-addons:6
>=dev-qt/qtquick3d-${QTMIN}:6
>=kde-frameworks/kirigami-${KFMIN}:6
>=kde-frameworks/kitemmodels-${KFMIN}:6
"
BDEPEND="
led? (
${RUST_DEPEND}
dev-build/corrosion
)
"
pkg_setup() {
use led && rust_pkg_setup
}
src_prepare() {
ecm_src_prepare
# TODO: upstream build switch?
if ! use led; then
cmake_comment_add_subdirectory kdeds
ecm_punt_bogus_dep Corrosion
ecm_punt_bogus_dep KF6 Auth
ecm_punt_bogus_dep KF6 DBusAddons
fi
}
src_configure() {
# Rust extensions are incompatible with C/C++ LTO compiler see e.g.
# https://bugs.gentoo.org/910220
filter-lto
local mycmakeargs=(
$(cmake_use_find_package alternate-calendar ICU)
$(cmake_use_find_package share KF6Purpose)
$(cmake_use_find_package webengine Qt6WebEngineQuick)
)
ecm_src_configure
}
pkg_postinst() {
optfeature "Disk quota applet" "sys-fs/quota"
xdg_pkg_postinst
}
|
