1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
|
# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
PYTHON_COMPAT=( python3_{13..14} )
inherit cmake locale-utils optfeature python-single-r1 xdg
DESCRIPTION="Simple but powerful Qt-based image viewer"
HOMEPAGE="https://photoqt.org/"
SRC_URI="https://gitlab.com/lspies/photoqt/-/archive/v${PV}/${PN}-v${PV}.tar.bz2"
S="${WORKDIR}/${PN}-v${PV}"
LICENSE="GPL-2+"
SLOT="0"
KEYWORDS="amd64"
IUSE="barcode chromecast devil exif extensions ffmpegthumbnailer geolocation graphicsmagick +imagemagick lcms mpv pdf raw test vips wayland"
REQUIRED_USE="chromecast? ( ${PYTHON_REQUIRED_USE} )"
RESTRICT="!test? ( test )"
# slot op: Uses Qt::GuiPrivate for rhi/qrhi.h
COMMON_DEPEND="
app-arch/libarchive:=
dev-qt/qtbase:6=[concurrent,dbus,gui,icu,network,opengl,sql,sqlite,widgets,xml]
dev-qt/qtdeclarative:6[opengl]
dev-qt/qtimageformats:6
dev-qt/qtmultimedia:6[qml]
dev-qt/qtquick3d:6
dev-qt/qtsvg:6
barcode? ( media-libs/zxing-cpp:= )
chromecast? (
${PYTHON_DEPS}
$(python_gen_cond_dep 'dev-python/pychromecast[${PYTHON_USEDEP}]')
)
devil? ( media-libs/devil )
exif? ( media-gfx/exiv2:=[bmff] )
extensions? ( dev-cpp/yaml-cpp:= )
ffmpegthumbnailer? ( media-video/ffmpegthumbnailer )
imagemagick? (
!graphicsmagick? ( media-gfx/imagemagick:=[cxx,hdri] )
graphicsmagick? ( media-gfx/graphicsmagick:=[cxx] )
)
lcms? ( media-libs/lcms:2 )
mpv? ( media-video/mpv:=[libmpv] )
pdf? ( app-text/poppler[qt6] )
raw? ( media-libs/libraw:= )
vips? (
dev-libs/glib:2
media-libs/vips:=
)
wayland? ( dev-libs/wayland )
"
RDEPEND="
${COMMON_DEPEND}
geolocation? (
dev-qt/qtlocation:6
dev-qt/qtpositioning:6[qml]
)
"
PDEPEND="extensions? ( ~media-plugins/photoqt-extensions-${PV} )"
DEPEND="
${COMMON_DEPEND}
vips? ( x11-base/xorg-proto )
"
BDEPEND="
dev-qt/qttools:6[linguist]
>=kde-frameworks/extra-cmake-modules-6.5.0:*
virtual/pkgconfig
chromecast? ( ${PYTHON_DEPS} )
"
PATCHES=(
"${FILESDIR}"/${P}-fix_segfault_gm.patch
)
pkg_setup() {
use chromecast && python-single-r1_pkg_setup
}
src_configure() {
local mycmakeargs=(
# required for extensions dir
-DCMAKE_CXX_FLAGS_RELWITHDEBINFO="-DNDEBUG"
-DWITH_ZXING=$(usex barcode)
-DWITH_CHROMECAST=$(usex chromecast)
-DWITH_DEVIL=$(usex devil)
-DWITH_EXIV2=$(usex exif)
-DWITH_EXIV2_ENABLE_BMFF=$(usex exif)
-DWITH_EXTENSIONS_NONSYS_OPENSSL=OFF # do not sign SO for now
-DWITH_EXTENSIONS_SUPPORT=$(usex extensions)
-DWITH_FFMPEGTHUMBNAILER=$(usex ffmpegthumbnailer)
-DWITH_LOCATION=$(usex geolocation)
-DWITH_GRAPHICSMAGICK=$(usex graphicsmagick $(usex imagemagick))
-DWITH_IMAGEMAGICK=$(usex imagemagick $(usex !graphicsmagick))
-DWITH_LCMS2=$(usex lcms)
-DWITH_VIDEO_MPV=$(usex mpv)
-DWITH_POPPLER=$(usex pdf)
-DWITH_LIBRAW=$(usex raw)
-DWITH_LIBVIPS=$(usex vips)
-DWITH_PHOTOSPHERE=ON
-DWITH_PHOTOSPHERE_QRHI=ON
-DWITH_WAYLANDSPECIFIC=$(usex wayland)
-DWITH_ADAPTSOURCE=ON # adapt the sources according to the Qt version
-DWITH_LIBSAI=OFF # Wunkolo/libsai, no release, experimental
-DWITH_QTPDF=OFF # use poppler instead
-DWITH_RESVG=OFF # qt5 only
-DWITH_TESTING=$(usex test)
)
cmake_src_configure
}
src_test() {
local -x QT_QPA_PLATFORM=offscreen
# QCollator::setNumericMode is not supported w/ POSIX/C locale or w/o icu
# Required for PQTScriptsFilesPaths::getFoldersIn()
local -x LOCPATH LC_ALL
if ! elocale_gen --set LC_ALL en_US.UTF-8; then
local CMAKE_SKIP_TESTS=( pqt_scriptsfilespaths )
fi
cmake_src_test -j1
}
pkg_postinst() {
optfeature "additional image formats like AVIF, EPS, HEIF/HEIC, PSD, etc." "kde-frameworks/kimageformats:6"
xdg_pkg_postinst
}
|
