blob: afbcebfe36591ac60e1d43fad99a64f0cb569eb2 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
|
# Copyright 1999-2025 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
CMAKE_MAKEFILE_GENERATOR="emake"
inherit cmake flag-o-matic toolchain-funcs
MY_COMMIT="376c1469eebedcc724dbbcc0d45030f32c9d13f5"
DESCRIPTION="Core libraries for simple video cutting, filtering and encoding tasks"
HOMEPAGE="http://fixounet.free.fr/avidemux/"
SRC_URI="https://github.com/mean00/avidemux2/archive/${MY_COMMIT}.tar.gz -> avidemux-${PV}.tar.gz"
S="${WORKDIR}/avidemux2-${MY_COMMIT}"
CMAKE_USE_DIR="${S}/${PN/-/_}"
# Multiple licenses because of all the bundled stuff.
# See License.txt.
LICENSE="GPL-2 MIT PSF-2 LGPL-2 OFL-1.1"
SLOT="2.7"
KEYWORDS="~amd64 ~x86"
IUSE="debug nls nvenc vaapi vdpau xv"
DEPEND="
dev-db/sqlite:3
virtual/zlib:=
nvenc? ( media-libs/nv-codec-headers )
vaapi? (
media-libs/libva:=[X]
x11-libs/libX11
)
vdpau? (
x11-libs/libvdpau
x11-libs/libX11
)
xv? (
x11-libs/libX11
x11-libs/libXext
x11-libs/libXv
)
"
RDEPEND="
${DEPEND}
!<media-libs/avidemux-core-${PV}
!<media-video/avidemux-${PV}
nls? ( virtual/libintl )
"
BDEPEND="
dev-lang/yasm[nls=]
virtual/pkgconfig
nls? ( sys-devel/gettext )
"
PATCHES=(
"${FILESDIR}"/avidemux-core-2.8.1_p20251019-ffmpeg-flags.patch
)
src_prepare() {
cmake_src_prepare
local ffmpeg_args=(
--cxx=$(tc-getCXX)
--nm=$(tc-getNM)
--ranlib=$(tc-getRANLIB)
--pkg-config=$(tc-getPKG_CONFIG)
# avoid automagic with libdrm, vaapi, vdpau ...
--disable-autodetect
$(tc-is-lto && echo --enable-lto) #966255
"--optflags='${CFLAGS} -std=gnu17'"
)
sed -i -e "s#@@GENTOO_FFMPEG_FLAGS@@#${ffmpeg_args[*]}#" avidemux_core/cmake/ffmpeg_configure.sh.cmake || die
}
src_configure() {
# See bug 432322.
use x86 && replace-flags -O0 -O1
local mycmakeargs=(
-DADM_DEBUG="$(usex debug)"
-DVERBOSE=ON
-DGETTEXT="$(usex nls)"
-DLIBVA="$(usex vaapi)"
-DNVENC="$(usex nvenc)"
-DVDPAU="$(usex vdpau)"
-DXVIDEO="$(usex xv)"
)
cmake_src_configure
}
|
