blob: 9388cd22d5cdc3a9e7b4d87e03b00b9ec94e3e1d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
|
# Copyright 2023-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
PYTHON_COMPAT=( python3_{13..14} )
inherit flag-o-matic meson python-any-r1 toolchain-funcs vala
DESCRIPTION="VIPS Image Processing Library"
HOMEPAGE="https://libvips.github.io/libvips/"
SRC_URI="https://github.com/libvips/libvips/releases/download/v${PV}/${P}.tar.xz"
LICENSE="LGPL-2.1+ MIT"
SLOT="0/42" # soname
KEYWORDS="amd64 ~arm64 ~riscv ~x86"
IUSE="
archive deprecated doc exif fftw fits fontconfig graphicsmagick
heif +highway imagemagick imagequant +introspection +jpeg jpeg2k
jpegxl lcms matio openexr orc pango pdf +png raw svg test tiff
vala webp
"
REQUIRED_USE="
doc? ( introspection )
fontconfig? ( pango )
graphicsmagick? ( imagemagick )
test? ( jpeg png webp )
vala? ( introspection )
"
RESTRICT="!test? ( test )"
RDEPEND="
dev-libs/glib:2
dev-libs/expat
virtual/libintl
archive? ( app-arch/libarchive:= )
exif? ( media-libs/libexif )
fftw? ( sci-libs/fftw:3.0= )
fits? ( sci-libs/cfitsio:= )
fontconfig? ( media-libs/fontconfig )
heif? ( media-libs/libheif:= )
highway? ( >=dev-cpp/highway-1.0.5 )
!highway? (
orc? ( dev-lang/orc )
)
imagemagick? (
graphicsmagick? ( media-gfx/graphicsmagick:= )
!graphicsmagick? ( media-gfx/imagemagick:= )
)
imagequant? ( media-gfx/libimagequant )
introspection? ( >=dev-libs/gobject-introspection-1.82.0-r2 )
jpeg? ( media-libs/libjpeg-turbo:= )
jpeg2k? ( media-libs/openjpeg:= )
jpegxl? ( media-libs/libjxl:= )
lcms? ( media-libs/lcms:2 )
matio? ( sci-libs/matio:= )
openexr? ( media-libs/openexr:= )
pango? (
x11-libs/cairo
x11-libs/pango
)
pdf? (
app-text/poppler[cairo]
x11-libs/cairo
)
png? ( media-libs/libpng:= )
raw? ( media-libs/libraw:= )
svg? (
gnome-base/librsvg:2
virtual/zlib:=
x11-libs/cairo
)
tiff? ( media-libs/tiff:= )
webp? ( media-libs/libwebp:= )
"
DEPEND="
${RDEPEND}
pango? ( x11-base/xorg-proto )
pdf? ( x11-base/xorg-proto )
svg? ( x11-base/xorg-proto )
test? (
tiff? ( media-libs/tiff[jpeg] )
)
"
BDEPEND="
dev-util/glib-utils
sys-devel/gettext
doc? (
${PYTHON_DEPS}
app-text/doxygen
dev-util/gi-docgen
media-gfx/graphviz
)
vala? ( $(vala_depend) )
"
pkg_setup() {
use doc && python-any-r1_pkg_setup
}
src_prepare() {
default
use vala && vala_setup
sed -i "/subdir('fuzz')/d" meson.build || die
}
src_configure() {
# workaround for segfault issue in LLVM lto (bug #921728)
tc-is-clang && filter-lto
local emesonargs=(
$(meson_use deprecated)
$(meson_use doc cpp-docs)
$(meson_use doc docs)
-Dexamples=false
$(meson_use vala vapi)
-Dcgif=disabled # not packaged, and not used to view gif (only saving)
$(meson_feature archive)
$(meson_feature exif)
$(meson_feature fftw)
$(meson_feature fits cfitsio)
$(meson_feature fontconfig)
$(meson_feature heif)
$(meson_feature highway)
$(meson_feature imagemagick magick)
-Dmagick-package=$(usex graphicsmagick GraphicsMagick MagickCore)
$(meson_feature imagequant)
$(meson_feature introspection)
$(meson_feature jpeg)
$(meson_feature jpeg2k openjpeg)
$(meson_feature jpegxl jpeg-xl)
$(meson_feature lcms)
$(meson_feature matio)
-Dnifti=disabled # not packaged
$(meson_feature openexr)
-Dopenslide=disabled # not packaged
$(meson_feature orc) # no-op if USE=highway is set
$(meson_feature pango pangocairo)
-Dpdfium=disabled # not packaged, can use poppler instead
$(meson_feature png)
$(meson_feature pdf poppler)
-Dquantizr=disabled # not packaged, can use imagequant instead
$(meson_feature raw)
-Dspng=disabled # not packaged, and libpng is preferred
$(meson_feature svg rsvg)
$(meson_feature tiff)
-Duhdr=disabled # not packaged
$(meson_feature webp)
$(meson_feature svg zlib) # zlib is currently only used by svgload.c
)
meson_src_configure
}
src_install() {
meson_src_install
if use doc; then
mkdir -p "${ED}"/usr/share/doc/${PF}/html || die
mv -- "${ED}"/usr/share/doc/{vips,${PF}/html/vips} || die
mv -- "${ED}"/usr/share/doc/{vips-cpp/html,${PF}/html/vips-cpp} || die
rmdir -- "${ED}"/usr/share/doc/vips-cpp || die
fi
}
|
