blob: a324feb7ae28d7871a495d0b3183828360249081 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
|
# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
GUILE_REQ_USE="deprecated,regex"
GUILE_COMPAT=( 3-0 )
PYTHON_COMPAT=( python3_{13..14} )
inherit elisp-common autotools guile-single python-single-r1 toolchain-funcs xdg-utils
if [[ ${PV} == *9999* ]]; then
inherit git-r3
EGIT_REPO_URI="https://git.savannah.gnu.org/git/lilypond.git"
else
MAIN_VER=$(ver_cut 1-2)
SRC_URI="https://lilypond.org/download/sources/v${MAIN_VER}/${P}.tar.gz"
KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~riscv ~x86"
fi
DESCRIPTION="GNU Music Typesetter"
HOMEPAGE="http://lilypond.org/"
LICENSE="GPL-3 FDL-1.3"
SLOT="0"
LANG_USE="l10n_ca l10n_cs l10n_de l10n_en l10n_fr l10n_hu l10n_it l10n_ja l10n_nl l10n_pt l10n_zh"
IUSE="debug doc emacs profile ${LANG_USE}"
unset LANG_USE
REQUIRED_USE="${GUILE_REQUIRED_USE} ${PYTHON_REQUIRED_USE}"
BDEPEND="
app-text/t1utils
dev-texlive/texlive-metapost
dev-lang/perl
dev-libs/kpathsea
>=media-gfx/fontforge-20200314[png,python]
>=sys-apps/texinfo-6.8
>=sys-devel/bison-2.4.1
sys-devel/flex
sys-devel/gettext
virtual/pkgconfig
doc? (
dev-texlive/texlive-langcyrillic
l10n_cs? ( dev-texlive/texlive-xetex )
l10n_ja? ( dev-texlive/texlive-langjapanese )
l10n_zh? ( dev-texlive/texlive-langchinese )
)
"
RDEPEND="
app-text/ghostscript-gpl
dev-libs/boehm-gc
>=dev-libs/glib-2.64:2
dev-libs/libatomic_ops
media-fonts/tex-gyre
>=media-libs/fontconfig-2.13
>=media-libs/freetype-2.10:2
media-libs/harfbuzz
>=media-libs/libpng-1.6.0
>=x11-libs/cairo-1.16
>=x11-libs/pango-1.44.5
virtual/zlib:=
emacs? ( >=app-editors/emacs-23.1:* )
${GUILE_DEPS}
${PYTHON_DEPS}
"
DEPEND="
${RDEPEND}
"
# Correct output data for tests isn't bundled with releases
RESTRICT="test"
DOCS=( DEDICATION README.md ROADMAP )
QA_PREBUILT="usr/*/${PN}/${PV}/ccache/*"
pkg_setup() {
guile-single_pkg_setup
python-single-r1_pkg_setup
}
src_prepare() {
guile-single_src_prepare
# respect CFLAGS
sed -i 's/OPTIMIZE -g/OPTIMIZE/' aclocal.m4 || die
eautoreconf
xdg_environment_reset #586592
}
src_configure() {
# fix hardcoded `ar`
sed -i "s/AR=ar/AR=$(tc-getAR)/g" flower/GNUmakefile || die "Failed to fix ar command"
local myeconfargs=(
--disable-optimising
--disable-pipe
$(use_enable debug debugging)
$(use_enable doc documentation)
$(use_enable profile profiling)
)
export VARTEXFONTS="${T}/fonts" # https://bugs.gentoo.org/692010
econf "${myeconfargs[@]}" AR="$(tc-getAR)"
}
src_compile() {
default
# http://lilypond.org/doc/v2.24/Documentation/changes/index#notes-for-source-compilation-and-packagers
emake bytecode
use doc && emake LANGS="${L10N}" doc info
if use emacs ; then
elisp-compile elisp/lilypond-{font-lock,indent,mode,what-beat}.el \
|| die "elisp-compile failed"
fi
}
src_install() {
emake DESTDIR="${D}" vimdir=/usr/share/vim/vimfiles install install-bytecode
use doc && emake DESTDIR="${D}" install-doc
# remove elisp files since they are in the wrong directory
rm -r "${ED}"/usr/share/emacs || die
if use emacs ; then
elisp-install ${PN} elisp/*.{el,elc} elisp/out/*.el \
|| die "elisp-install failed"
elisp-site-file-install "${FILESDIR}"/50${PN}-gentoo.el
fi
guile_unstrip_ccache
python_fix_shebang "${ED}"
einstalldocs
}
pkg_postinst() {
use emacs && elisp-site-regen
}
pkg_postrm() {
use emacs && elisp-site-regen
}
|
