blob: c9e4522d6b46848df4ab3080ec36d9bf4291a7b8 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
|
# Copyright 1999-2025 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
GENTOO_DEPEND_ON_PERL=no
inherit autotools flag-o-matic perl-module
DESCRIPTION="Hub software for Direct Connect, fork of opendchub"
HOMEPAGE="https://sourceforge.net/projects/dbhub/"
SRC_URI="https://downloads.sourceforge.net/${PN}/${P}.tbz2"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
IUSE="debug nls perl switch-user ${GENTOO_PERL_USESTRING}"
DEPEND="
virtual/libcrypt:=
perl? (
${GENTOO_PERL_DEPSTRING}
dev-lang/perl:=
)
switch-user? ( sys-libs/libcap )
"
RDEPEND="${DEPEND}"
PATCHES=(
"${FILESDIR}"/${PN}-gentoo.patch
"${FILESDIR}"/${PN}-no-dynaloader.patch
"${FILESDIR}"/${PN}-fix-buffer-overflows.patch
)
src_prepare() {
default
eautoreconf
}
src_configure() {
append-flags -fcommon
# bashism in perl check
CONFIG_SHELL="${BROOT}"/bin/bash econf \
$(use_enable debug) \
$(use_enable nls) \
$(use_enable perl) \
$(use_enable switch-user switch_user)
}
src_compile() {
# Avoid perl-module_src_compile (bug #963096)
default
}
src_test() {
# Avoid perl-module_src_test (bug #963096)
default
}
src_install() {
# Avoid perl-module_src_install (bug #963096)
default
}
|
