1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
|
# Copyright 2019-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
PYTHON_COMPAT=( python3_{13..14} )
inherit python-any-r1 toolchain-funcs
DESCRIPTION="BLAS-like Library Instantiation Software Framework"
HOMEPAGE="https://github.com/flame/blis"
SRC_URI="https://github.com/flame/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
LICENSE="BSD"
# SOVERSION; but 2.0 introduced some breaking changes
SLOT="0/4-2.0"
KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
CPU_USE=(
cpu_flags_ppc_{vsx,vsx3}
cpu_flags_arm_{neon,v7,v8,sve}
cpu_flags_x86_{ssse3,avx,fma3,fma4,avx2,avx512vl}
)
IUSE="doc eselect-ldso index64 openmp pthread serial static-libs ${CPU_USE[@]}"
REQUIRED_USE="?? ( openmp pthread serial )"
DEPEND="
eselect-ldso? (
!app-eselect/eselect-cblas
>=app-eselect/eselect-blas-0.2
)
"
RDEPEND="
${DEPEND}
"
BDEPEND="
${PYTHON_DEPS}
dev-lang/perl
"
PATCHES=(
# TODO: remove this when we remove eselect-ldso
"${FILESDIR}"/${PN}-0.6.0-blas-provider.patch
# to prevent QA Notice: pkg-config files with wrong LDFLAGS detected
"${FILESDIR}"/${PN}-0.8.1-pkg-config.patch
"${FILESDIR}"/${PN}-0.9.0-rpath.patch
)
get_confname() {
local confname=generic
if use x86 || use amd64; then
use cpu_flags_x86_ssse3 && confname=penryn
use cpu_flags_x86_avx && use cpu_flags_x86_fma3 && confname=sandybridge
use cpu_flags_x86_avx && use cpu_flags_x86_fma4 && confname=bulldozer
use cpu_flags_x86_avx && use cpu_flags_x86_fma4 && use cpu_flags_x86_fma3 && confname=piledriver
use cpu_flags_x86_avx2 && confname=haswell
use cpu_flags_x86_avx512vl && confname=skx
elif use arm || use arm64; then
use arm && confname=arm32
use arm64 && confname=arm64
use cpu_flags_arm_neon && use cpu_flags_arm_v7 && confname=cortexa9
use cpu_flags_arm_v8 && confname=cortexa53
use cpu_flags_arm_sve && confname=armsve
elif use ppc || use ppc64; then
confname=power
use cpu_flags_ppc_vsx && confname=power7
use cpu_flags_ppc_vsx3 && confname=power9
fi
echo ${confname}
}
src_configure() {
# This is not an autotools configure file. We don't use econf here.
local myconf=(
--enable-verbose-make
--prefix="${EPREFIX}/usr"
--libdir="${EPREFIX}/usr/$(get_libdir)"
$(use_enable static-libs static)
--enable-blas
--enable-cblas
--enable-shared
)
if use openmp; then
myconf+=( -t openmp )
elif use pthread; then
myconf+=( -t pthreads )
else
myconf+=( -t no )
fi
# confname must always come last
myconf+=( "$(get_confname)" )
local -x CC="$(tc-getCC)"
local -x AR="$(tc-getAR)"
local -x RANLIB="$(tc-getRANLIB)"
if use index64; then
einfo "Configuring ILP64 variant"
cp -r "${S}" "${S}-ilp64" || die
pushd "${S}-ilp64" >/dev/null || die
./configure -b 64 -i 64 "${myconf[@]}" || die
popd >/dev/null || die
fi
einfo "Configuring LP64 variant"
./configure "${myconf[@]}" || die
}
emake64() {
local overrides=(
LIBBLIS=libblis64
MK_INCL_DIR_INST="${ED}/usr/include/blis64"
)
emake -C "${S}-ilp64" "${overrides[@]}" "${@}"
}
src_compile() {
local -x DEB_LIBBLAS=libblas.so.3
local -x DEB_LIBCBLAS=libcblas.so.3
local -x LDS_BLAS="${FILESDIR}"/blas.lds
local -x LDS_CBLAS="${FILESDIR}"/cblas.lds
use index64 && emake64
emake
}
src_test() {
local -x LD_LIBRARY_PATH="lib/$(get_confname)"
emake testblis-fast
./testsuite/check-blistest.sh ./output.testsuite || die
if use index64; then
emake64 testblis-fast
./testsuite/check-blistest.sh "${S}-ilp64"/output.testsuite || die
fi
}
src_install() {
local libroot=/usr/$(get_libdir)
local install_args=(
DESTDIR="${D}"
# remove weird Makefile configs, they're incorrect for index64
# and nothing should be using them anyway
MK_SHARE_DIR_INST="${T}/discard"
# upstream installs .pc file to share, sigh
PC_SHARE_DIR_INST="${ED}${libroot}/pkgconfig"
# do not install "helper" (top-level) headers
HELP_HEADERS_INSTALLED=
HELP_HEADERS_TO_INSTALL=
)
emake "${install_args[@]}" install
if use index64; then
emake64 "${install_args[@]}" install
# we need to make blis64.pc with proper subst ourselves
sed -e 's:blis:&64:' "${ED}${libroot}/pkgconfig"/blis.pc \
> "${ED}${libroot}/pkgconfig"/blis64.pc || die
fi
use doc && dodoc README.md docs/*.md
if use eselect-ldso; then
insinto "${libroot}/blas/blis"
doins lib/*/lib{c,}blas.so.3
dosym libblas.so.3 "${libroot}/blas/blis/libblas.so"
dosym libcblas.so.3 "${libroot}/blas/blis/libcblas.so"
fi
}
pkg_postinst() {
use eselect-ldso || return
local libdir=$(get_libdir) me="blis"
# check blas
eselect blas add ${libdir} "${EROOT}"/usr/${libdir}/blas/${me} ${me}
local current_blas=$(eselect blas show ${libdir} | cut -d' ' -f2)
if [[ ${current_blas} == "${me}" || -z ${current_blas} ]]; then
eselect blas set ${libdir} ${me}
elog "Current eselect: BLAS/CBLAS (${libdir}) -> [${me}]."
else
elog "Current eselect: BLAS/CBLAS (${libdir}) -> [${current_blas}]."
elog "To use blas [${me}] implementation, you have to issue (as root):"
elog "\t eselect blas set ${libdir} ${me}"
fi
}
pkg_postrm() {
use eselect-ldso && eselect blas validate
}
|
