blob: cd672f4a50053147ac4dc9d07043c558e9e7fe8e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
|
# Copyright 1999-2025 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DOCS_BUILDER="doxygen"
DOCS_DIR="docs/doxygen"
DOCS_DEPEND="media-gfx/graphviz"
LLVM_COMPAT=( 20 )
ROCM_VERSION=${PV}
inherit cmake docs edo flag-o-matic multiprocessing rocm llvm-r1
DESCRIPTION="AMD's library for BLAS on ROCm"
HOMEPAGE="https://github.com/ROCm/rocBLAS"
SRC_URI="https://github.com/ROCm/rocBLAS/archive/rocm-${PV}.tar.gz -> rocm-${P}.tar.gz"
S="${WORKDIR}/${PN}-rocm-${PV}"
LICENSE="BSD"
SLOT="0/$(ver_cut 1-2)"
KEYWORDS="~amd64"
IUSE="benchmark hipblaslt test video_cards_amdgpu"
RESTRICT="!test? ( test )"
REQUIRED_USE="${ROCM_REQUIRED_USE}"
BDEPEND="
>=dev-build/rocm-cmake-5.3
"
RDEPEND="
dev-util/hip:${SLOT}
dev-util/roctracer:${SLOT}
hipblaslt? ( sci-libs/hipBLASLt:${SLOT} )
benchmark? (
virtual/blas
dev-cpp/gtest
llvm-runtimes/openmp
)
"
DEPEND="
${RDEPEND}
>=dev-cpp/msgpack-cxx-6.0.0
test? (
virtual/blas
dev-cpp/gtest
llvm-runtimes/openmp
)
video_cards_amdgpu? (
dev-util/Tensile:${SLOT}
)
"
QA_FLAGS_IGNORED="/usr/lib64/rocblas/library/.*"
PATCHES=(
"${FILESDIR}"/${PN}-5.4.2-add-missing-header.patch
"${FILESDIR}"/${PN}-5.4.2-link-cblas.patch
"${FILESDIR}"/${PN}-6.0.2-expand-isa-compatibility.patch
"${FILESDIR}"/${PN}-6.3.0-no-git.patch
"${FILESDIR}"/${PN}-6.3.0-find-cblas.patch
)
src_prepare() {
cmake_src_prepare
sed -e "s:,-rpath=.*\":\":" -i clients/CMakeLists.txt || die
}
src_configure() {
llvm_prepend_path "${LLVM_SLOT}"
rocm_use_clang
# too many warnings
append-cxxflags -Wno-explicit-specialization-storage-class -Wno-unused-value
local mycmakeargs=(
-DCMAKE_SKIP_RPATH=ON
-DBUILD_FILE_REORG_BACKWARD_COMPATIBILITY=OFF
-DROCM_SYMLINK_LIBS=OFF
-DAMDGPU_TARGETS="$(get_amdgpu_flags)"
-DBUILD_WITH_TENSILE="$(usex video_cards_amdgpu)"
-DCMAKE_INSTALL_INCLUDEDIR="include/rocblas"
-DBUILD_CLIENTS_SAMPLES=OFF
-DBUILD_CLIENTS_TESTS="$(usex test ON OFF)"
-DBUILD_CLIENTS_BENCHMARKS="$(usex benchmark ON OFF)"
-DBUILD_WITH_PIP=OFF
-DBUILD_WITH_HIPBLASLT="$(usex hipblaslt ON OFF)"
-DLINK_BLIS=OFF
-DTensile_CPU_THREADS=$(makeopts_jobs)
-Wno-dev
)
if usex video_cards_amdgpu; then
mycmakeargs+=(
-DTensile_COMPILER="hipcc"
-DTensile_ROOT="${EPREFIX}/usr/share/Tensile"
-DTensile_CPU_THREADS="$(makeopts_jobs)"
)
fi
cmake_src_configure
}
src_compile() {
docs_compile
cmake_src_compile
}
src_test() {
check_amdgpu
cd "${BUILD_DIR}"/clients/staging || die
export ROCBLAS_TEST_TIMEOUT=3600 ROCBLAS_TENSILE_LIBPATH="${BUILD_DIR}/Tensile/library"
export LD_LIBRARY_PATH="${BUILD_DIR}/clients:${BUILD_DIR}/library/src"
# `--gtest_filter=*quick*:*pre_checkin*-*known_bug*` is >1h on 7900XTX
edob ./rocblas-test --yaml rocblas_smoke.yaml
}
src_install() {
cmake_src_install
if use benchmark; then
cd "${BUILD_DIR}" || die
dolib.a clients/librocblas_fortran_client.a
dobin clients/staging/rocblas-bench
fi
# Stop llvm-strip from removing .strtab section from *.hsaco files,
# otherwise rocclr/elf/elf.cpp complains with "failed: null sections(STRTAB)" and crashes
dostrip -x "/usr/$(get_libdir)/rocblas/library/"
}
|
