blob: 32b7cbaca41d6f9e723f1cca3a506263310bb8b0 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
|
# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
MAJOR="$(ver_cut 1)"
CADABRA="${PN}${MAJOR}"
BUNDLED_MICROTEX_SUBMODULE_SHA="9dd1fb04884cbb1701806c6ad6f5405b4f01d934"
PYTHON_COMPAT=( python3_{13..14} )
inherit xdg-utils python-single-r1 cmake
DESCRIPTION="Field-theory motivated approach to computer algebra"
HOMEPAGE="https://cadabra.science/
https://github.com/kpeeters/cadabra2/"
if [[ "${PV}" == *9999* ]] ; then
inherit git-r3
EGIT_REPO_URI="https://github.com/kpeeters/${CADABRA}"
else
SRC_URI="
https://github.com/kpeeters/${CADABRA}/archive/${PV/_p/-p}.tar.gz
-> ${P}.gh.tar.gz
https://github.com/kpeeters/MicroTeX/archive/${BUNDLED_MICROTEX_SUBMODULE_SHA}.tar.gz
-> microtex-${BUNDLED_MICROTEX_SUBMODULE_SHA}.gh.tar.gz
"
S="${WORKDIR}/${CADABRA}-${PV/_p/-p}"
KEYWORDS="amd64 ~x86"
fi
LICENSE="GPL-3"
SLOT="0/${MAJOR}"
IUSE="gui +jupyter test"
REQUIRED_USE="${PYTHON_REQUIRED_USE}"
RESTRICT="!test? ( test )"
RDEPEND="
${PYTHON_DEPS}
app-text/dvipng
dev-cpp/glibmm:2
dev-db/sqlite:3=
dev-libs/boost:=
dev-libs/gmp:=[cxx]
dev-libs/jsoncpp:=
dev-libs/libsigc++:2
dev-texlive/texlive-basic
$(python_gen_cond_dep '
dev-python/gmpy2:2[${PYTHON_USEDEP}]
dev-python/matplotlib[${PYTHON_USEDEP}]
dev-python/sympy[${PYTHON_USEDEP}]
jupyter? (
dev-python/jupyter[${PYTHON_USEDEP}]
)
')
gui? (
dev-cpp/gtkmm:3.0
)
"
DEPEND="
${RDEPEND}
"
BDEPEND="
$(python_gen_cond_dep '
dev-python/pybind11[${PYTHON_USEDEP}]
')
"
PATCHES=(
"${FILESDIR}/${CADABRA}-2.5.14-CMakeLists-txt.patch"
"${FILESDIR}/${CADABRA}-2.5.14-c++lib-CMakeLists-txt.patch"
"${FILESDIR}/${CADABRA}-2.5.14-frontend-gtkmm-CMakeLists-txt.patch"
"${FILESDIR}/${CADABRA}-2.5.14-tests-CMakeLists-txt.patch"
)
DOCS=( CODE_OF_CONDUCT.md CONTRIBUTING.md JUPYTER.rst README.rst )
src_prepare() {
# Bundled submodules
mkdir -p ./submodules/microtex/ || die
cp -r -l "${WORKDIR}/MicroTeX-${BUNDLED_MICROTEX_SUBMODULE_SHA}"/* \
./submodules/microtex/ || die
# Clean postinst script which calls libtool and icon-cache update
echo '#!/bin/sh' > ./config/postinst.in || die
# Update minimum required CMake version.
find . -type f \
\( -iname "CMakeLists.txt" -o -iname "*.cmake" \) \
-exec sed -i {} \
-e "/cmake_minimum_required/I s|(.*)|(VERSION 3.30...4.0)|g" \
\; || die
cmake_src_prepare
}
src_configure() {
local -a mycmakeargs=(
-DPython_EXECUTABLE="${PYTHON}"
-DENABLE_SYSTEM_JSONCPP="ON"
-DPACKAGING_MODE="ON"
-DBUILD_AS_CPP_LIBRARY="OFF"
-DENABLE_JUPYTER="OFF" # For a special Xeus Jupyter kernel (uses xtl).
-DENABLE_MATHEMATICA="OFF"
-DINSTALL_TARGETS_ONLY="OFF"
-DBUILD_TESTS="$(usex test)"
-DENABLE_FRONTEND="$(usex gui)"
-DENABLE_PY_JUPYTER="$(usex jupyter)"
)
cmake_src_configure
}
src_install() {
cmake_src_install
python_optimize
}
pkg_postinst() {
if use gui ; then
xdg_icon_cache_update
xdg_desktop_database_update
xdg_mimeinfo_database_update
fi
}
pkg_postrm() {
if use gui ; then
xdg_icon_cache_update
xdg_desktop_database_update
xdg_mimeinfo_database_update
fi
}
|
