blob: baa888a9bc94dd4ed40543b054bc70784795eb9d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
|
# Copyright 2021-2025 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit autotools edo
DESCRIPTION="Wrapper to use non-BOINC apps with BOINC"
HOMEPAGE="https://github.com/BOINC/boinc/wiki/WrapperApp"
SRC_URI="https://github.com/BOINC/boinc/archive/refs/tags/wrapper/${PV}.tar.gz -> ${P}.tar.gz"
LICENSE="Info-ZIP LGPL-3+"
SLOT="0"
KEYWORDS="~amd64 ~arm64 ~x86"
RDEPEND="
dev-libs/libzip:=
virtual/zlib:=
"
DEPEND="${RDEPEND}"
DOCS=( job.xml )
PATCHES=(
"${FILESDIR}"/${PN}-26018-makefile.patch
)
QA_CONFIG_IMPL_DECL_SKIP=(
# https://bugs.gentoo.org/922046
"_mm*"
)
src_prepare() {
default
eautoreconf
}
src_configure() {
edo bash generate_svn_version.sh
local myeconfargs=(
# build libraries only
--enable-pkg-devel
--disable-fcgi
# link with libboinc_api statically
--disable-shared
--enable-static
# do not build libboinc_graphics
--without-x
ax_cv_check_gl_libgl=no
)
econf "${myeconfargs[@]}"
}
src_compile() {
emake
local wrapper_make_args=(
MAKEFILE_LDFLAGS="-lpthread"
MAKEFILE_STDLIB=
WRAPPER_RELEASE_SUFFIX=
)
emake -C samples/wrapper "${wrapper_make_args[@]}"
}
src_install() {
cd samples/wrapper || die
einstalldocs
newbin wrapper boinc-wrapper
}
|
