blob: 8090e703c51a9dd6dd40e675febd15e75af05652 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
|
# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit cmake flag-o-matic
MYP=HepMC-${PV}
DESCRIPTION="Event Record for Monte Carlo Generators"
HOMEPAGE="
https://hepmc.web.cern.ch/hepmc/
https://gitlab.cern.ch/hepmc/HepMC/
"
SRC_URI="https://hepmc.web.cern.ch/hepmc/releases/hepmc${PV}.tgz"
S="${WORKDIR}/${MYP}"
LICENSE="GPL-2"
SLOT="2"
KEYWORDS="~amd64 ~x86"
IUSE="cm doc examples gev test"
RESTRICT="!test? ( test )"
BDEPEND="
doc? (
app-text/doxygen[dot]
dev-texlive/texlive-latex
dev-texlive/texlive-latexextra
dev-texlive/texlive-latexrecommended
)
"
PATCHES=(
"${FILESDIR}"/${P}-cmake4.patch
"${FILESDIR}"/${P}-cmp0153.patch
)
src_prepare() {
cmake_src_prepare
cmake_comment_add_subdirectory doc
# CMake doc building broken
# gentoo doc directory
#sed -i \
# -e "s:share/HepMC/doc:share/doc/${PF}:" \
# doc/CMakeLists.txt || die
# gentoo examples directory
sed -i \
-e "s:share/HepMC:share/doc/${PF}:" \
$(find examples -name CMakeLists.txt) || die
# respect user's flags
sed -i \
-e "s/-O -ansi -pedantic -Wall//g" \
cmake/Modules/HepMCVariables.cmake || die
# gentoo libdir love
sed -i \
-e '/DESTINATION/s/lib/lib${LIB_SUFFIX}/g' \
{src,fio}/CMakeLists.txt || die
# remove targets if use flags not set
if ! use examples; then
cmake_comment_add_subdirectory examples
fi
if ! use test; then
cmake_comment_add_subdirectory test
fi
# remove static libs
sed -i \
-e '/(HepMC\(fio\|\)S/d' \
-e '/TARGETS/s/HepMC\(fio\|\)S//' \
{src,fio}/CMakeLists.txt || die
}
src_configure() {
# error: 'hepevt_' violates the C++ One Definition Rule [-Werror=odr]
# Bug 863284
filter-lto
# use MeV over GeV and mm over cm
local mycmakeargs=(
-Dlength=$(usex cm CM MM)
-Dmomentum=$(usex gev GEV MEV)
)
cmake_src_configure
}
src_compile() {
cmake_src_compile
if use doc; then
cd doc || die
./buildDoc.sh || die
./buildDoxygen.sh || die
HTML_DOCS=( doc/html/. )
fi
}
src_install() {
cmake_src_install
use doc && dodoc doc/*.pdf
}
|
