blob: 93b94263a244bbfecfc9043ffa141587e1dfc3d5 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
|
# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
PYTHON_COMPAT=( python3_{13..14} )
inherit meson python-any-r1 systemd
DESCRIPTION="Desktop integration portal"
HOMEPAGE="https://flatpak.github.io/xdg-desktop-portal/ https://github.com/flatpak/xdg-desktop-portal"
SRC_URI="https://github.com/flatpak/${PN}/releases/download/${PV}/${P}.tar.xz"
LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="amd64 arm arm64 ~loong ppc ppc64 ~riscv x86"
IUSE="geolocation flatpak gstreamer seccomp systemd test udev"
# Upstream expect flatpak to be used w/ seccomp and flatpak needs bwrap anyway
REQUIRED_USE="flatpak? ( seccomp )"
RESTRICT="!test? ( test ) gstreamer? ( test )"
PROPERTIES="gstreamer? ( test_privileged )"
DEPEND="
>=dev-libs/glib-2.72:2
dev-libs/json-glib
>=media-video/pipewire-0.3:=
>=sys-fs/fuse-3.10.0:3=[suid]
x11-libs/gdk-pixbuf
geolocation? ( >=app-misc/geoclue-2.5.3:2.0 )
gstreamer? (
media-libs/gst-plugins-base:1.0
sys-apps/bubblewrap
)
flatpak? ( sys-apps/flatpak )
seccomp? ( sys-apps/bubblewrap )
systemd? ( sys-apps/systemd )
udev? ( dev-libs/libgudev )
"
RDEPEND="
${DEPEND}
sys-apps/dbus
"
BDEPEND="
${PYTHON_DEPS}
>=dev-util/gdbus-codegen-2.80.5-r1
dev-python/docutils
sys-devel/gettext
virtual/pkgconfig
test? (
dev-util/umockdev
media-libs/gstreamer
media-libs/gst-plugins-good
$(python_gen_any_dep '
>=dev-python/pytest-3[${PYTHON_USEDEP}]
dev-python/pytest-xdist[${PYTHON_USEDEP}]
dev-python/python-dbusmock[${PYTHON_USEDEP}]
')
)
"
PATCHES=(
# Make gstreamer use optional
"${FILESDIR}/${PN}-1.20.4-optional-gstreamer.patch"
# These tests require connections to pipewire, internet, /dev/fuse
"${FILESDIR}/${PN}-1.20.0-sandbox-disable-failing-tests.patch"
)
python_check_deps() {
if use test; then
python_has_version ">=dev-python/pytest-3[${PYTHON_USEDEP}]" &&
python_has_version "dev-python/pytest-xdist[${PYTHON_USEDEP}]" &&
python_has_version "dev-python/python-dbusmock[${PYTHON_USEDEP}]"
fi
}
src_configure() {
if use gstreamer; then
# bug #951609, #972571
addpredict /dev
fi
local emesonargs=(
-Ddbus-service-dir="${EPREFIX}/usr/share/dbus-1/services"
-Dsystemd-user-unit-dir="$(systemd_get_userunitdir)"
$(meson_feature flatpak flatpak-interfaces)
$(meson_feature geolocation geoclue)
$(meson_feature udev gudev)
$(meson_feature seccomp sandboxed-image-validation)
$(meson_feature gstreamer sandboxed-sound-validation)
$(meson_feature systemd)
# Requires flatpak
-Ddocumentation=disabled
# -Dxmlto-flags=
-Ddatarootdir="${EPREFIX}/usr/share"
-Dman-pages=enabled
-Dinstalled-tests=false
$(meson_feature test tests)
)
meson_src_configure
}
src_test() {
# The default portage tmpdir is too long for dbus 99 byte limit for sockets
local -x TMPDIR="$(mktemp -d --tmpdir=/tmp ${PF}-XXX || die)"
nonfatal meson_src_test
local ret="${?}"
rm -r "${TMPDIR}" || die
if [[ "${ret}" != 0 ]]; then
die "tests failed"
fi
}
src_install() {
meson_src_install
# Install a default to avoid breakage: >=1.18.0 assumes that DEs/WMs
# will install their own, but we want some fallback in case they don't
# (so will probably keep this forever). DEs need time to catch up even
# if they will eventually provide one anyway. See bug #915356.
#
# TODO: Add some docs on wiki for users to add their own preference
# for minimalist WMs etc.
insinto /usr/share/xdg-desktop-portal
newins "${FILESDIR}"/default-portals.conf portals.conf
exeinto /etc/user/init.d
newexe "${FILESDIR}"/xdg-desktop-portal.initd xdg-desktop-portal
}
pkg_postinst() {
if ! has_version gui-libs/xdg-desktop-portal-lxqt && ! has_version gui-libs/xdg-desktop-portal-wlr && \
! has_version kde-plasma/xdg-desktop-portal-kde && ! has_version sys-apps/xdg-desktop-portal-gnome && \
! has_version sys-apps/xdg-desktop-portal-gtk && ! has_version sys-apps/xdg-desktop-portal-xapp; then
elog "${PN} is not usable without any of the following XDP"
elog "implementations installed:"
elog " gui-libs/xdg-desktop-portal-lxqt"
elog " gui-libs/xdg-desktop-portal-wlr"
elog " kde-plasma/xdg-desktop-portal-kde"
elog " sys-apps/xdg-desktop-portal-gnome"
elog " sys-apps/xdg-desktop-portal-gtk"
elog " sys-apps/xdg-desktop-portal-xapp"
fi
}
|
