blob: c0fc70e43b0374ca5a425a0d5f1aa5059ae5dd46 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
|
# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit go-env go-module shell-completion sysroot systemd
DESCRIPTION="Kubernetes Proxy service"
HOMEPAGE="https://github.com/kubernetes/kubernetes https://kubernetes.io"
SRC_URI="https://github.com/kubernetes/kubernetes/archive/v${PV}.tar.gz -> kubernetes-${PV}.tar.gz"
S=${WORKDIR}/kubernetes-${PV}
LICENSE="Apache-2.0"
# Dependent licenses
LICENSE+=" Apache-2.0 BSD BSD-2 ISC MIT"
SLOT="0"
KEYWORDS="amd64 ~arm64"
RESTRICT="test"
RDEPEND="net-firewall/conntrack-tools"
BDEPEND=">=dev-lang/go-1.26.0"
QA_PRESTRIPPED=usr/bin/kube-proxy
src_compile() {
local GOOS=$(go-env_goos)
emake -j1 GOFLAGS="${GOFLAGS}" GOLDFLAGS="" LDFLAGS="" FORCE_HOST_GO=yes \
KUBE_BUILD_PLATFORMS="${GOOS}/${GOARCH}" KUBE_${GOOS@U}_${GOARCH@U}_CC="${CC}" \
WHAT=cmd/${PN}
bin=_output/local/bin/${GOOS}/${GOARCH}/${PN}
einfo "generating shell completion files"
sysroot_try_run_prefixed ${bin} completion bash > ${PN}.bash || die
sysroot_try_run_prefixed ${bin} completion zsh > ${PN}.zsh || die
sysroot_try_run_prefixed ${bin} completion fish > ${PN}.fish || die
}
src_install() {
dobin ${bin}
[[ -s ${PN}.bash ]] && newbashcomp ${PN}.bash ${PN}
[[ -s ${PN}.zsh ]] && newzshcomp ${PN}.zsh _${PN}
[[ -s ${PN}.fish ]] && dofishcomp ${PN}.fish
keepdir /var/log/${PN} /var/lib/${PN}
newinitd "${FILESDIR}"/${PN}.initd ${PN}
newconfd "${FILESDIR}"/${PN}.confd ${PN}
systemd_dounit "${FILESDIR}"/${PN}.service
insinto /etc/logrotate.d
newins "${FILESDIR}"/${PN}.logrotated ${PN}
}
|
