blob: 870d0343e96e95fdc7c2fa0cc659172724c9ee89 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
|
# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=9
inherit toolchain-funcs
MY_P="${PN}-ng-${PV}"
DESCRIPTION="Mount archives using libarchive and FUSE"
HOMEPAGE="https://git.sr.ht/~nabijaczleweli/archivemount-ng"
SRC_URI="https://git.sr.ht/~nabijaczleweli/archivemount-ng/archive/${PV}.tar.gz -> ${MY_P}.tar.gz"
S="${WORKDIR}/${MY_P}"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
# Tests require access to /dev/fuse.
RESTRICT="test"
PROPERTIES="test_privileged"
RDEPEND="
app-arch/libarchive:=
sys-fs/fuse:3=
"
DEPEND="${RDEPEND}"
BDEPEND="virtual/pkgconfig"
src_compile() {
emake \
CC="$(tc-getCC)" \
CXX="$(tc-getCXX)" \
PKG_CONFIG="$(tc-getPKG_CONFIG)" \
SOURCE_DATE_EPOCH=$(stat -c %Y archivemount.1.in) \
VERSION="${PV}"
}
src_install() {
emake install \
PREFIX="${EPREFIX}/usr" \
DESTDIR="${D}"
}
src_test() {
addwrite /dev/fuse
default
}
|
