blob: e571795ca8beb2be70aca26ea77a7839e22a02c7 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
|
# Copyright 2019-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit edo ninja-utils toolchain-funcs xdg
if [[ "${PV}" == "9999" ]]
then
EGIT_REPO_URI="https://anongit.hacktivis.me/git/badwolf.git"
inherit git-r3
else
VERIFY_SIG_METHOD=signify
inherit savedconfig verify-sig
MY_P="${PN}-$(ver_rs 3 - 4 .)"
SRC_URI="
https://distfiles.hacktivis.me/releases/badwolf/${MY_P}.tar.gz
verify-sig? ( https://distfiles.hacktivis.me/releases/badwolf/${MY_P}.tar.gz.sign )
"
KEYWORDS="~amd64 ~arm64 ~ppc64"
S="${WORKDIR}/${MY_P}"
fi
DESCRIPTION="Minimalist and privacy-oriented WebKitGTK+ browser"
HOMEPAGE="https://hacktivis.me/projects/badwolf"
LICENSE="BSD"
SLOT="0"
IUSE="nls"
DOCS=("README.md" "KnowledgeBase.md")
DEPEND="
dev-libs/glib:2
dev-libs/libxml2:=
x11-libs/gtk+:3
net-libs/webkit-gtk:4.1=
"
RDEPEND="${DEPEND}"
BDEPEND="
app-alternatives/ninja
nls? ( sys-devel/gettext )
virtual/pkgconfig
"
if [[ "${PV}" != "9999" ]]
then
BDEPEND="${BDEPEND} verify-sig? ( sec-keys/signify-keys-lanodan:2025 )"
VERIFY_SIG_OPENPGP_KEY_PATH="/usr/share/signify-keys/signify-keys-lanodan-2025.pub"
src_unpack() {
if use verify-sig; then
# Too many levels of symbolic links
cd "${DISTDIR}" || die
cp ${A} "${WORKDIR}" || die
cd "${WORKDIR}" || die
verify-sig_verify_detached "${MY_P}.tar.gz" "${MY_P}.tar.gz.sign"
fi
default
}
fi
src_configure() {
[[ "${PV}" == "9999" ]] || restore_config config.h
edo ./configure \
CC="$(tc-getCC)" \
PKG_CONFIG="$(tc-getPKG_CONFIG)" \
CMD_ED="false" \
CFLAGS="${CFLAGS:--O2 -Wall -Wextra}" \
LDFLAGS="${LDFLAGS}" \
DOCDIR="/usr/share/doc/${PF}" \
PREFIX="/usr" \
WITH_WEBKITGTK="4.1" \
ENABLE_NLS="$(usex nls 1 0)"
}
src_compile() {
eninja
}
src_test() {
eninja test
}
src_install() {
DESTDIR="${ED}" eninja install
[[ "${PV}" == "9999" ]] || save_config config.h
}
|
