blob: cb9ee5340a04e867a8218d12cc96c1a2db372088 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
|
# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit flag-o-matic gnome2-utils meson-multilib xdg
DESCRIPTION="Internationalized text layout and rendering library"
HOMEPAGE="https://www.gtk.org/docs/architecture/pango https://gitlab.gnome.org/GNOME/pango"
SRC_URI="https://download.gnome.org/sources/pango/$(ver_cut 1-2)/${P}.tar.xz"
LICENSE="LGPL-2+"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
IUSE="debug examples libthai gtk-doc +introspection sysprof test X"
REQUIRED_USE="gtk-doc? ( introspection )"
RESTRICT="!test? ( test )"
RDEPEND="
>=dev-libs/glib-2.88:2[${MULTILIB_USEDEP}]
>=dev-libs/fribidi-1.0.6[${MULTILIB_USEDEP}]
>=media-libs/harfbuzz-11.0.0:=[glib(+),introspection?,truetype(+),${MULTILIB_USEDEP}]
>=media-libs/fontconfig-2.17.0:1.0[${MULTILIB_USEDEP}]
>=x11-libs/cairo-1.18.0[X?,${MULTILIB_USEDEP}]
>=media-libs/freetype-2.5.0.1:2[harfbuzz,png,${MULTILIB_USEDEP}]
introspection? ( >=dev-libs/gobject-introspection-1.83.2:= )
libthai? ( dev-libs/libthai:= )
sysprof? ( >=dev-util/sysprof-capture-3.40.1:4[${MULTILIB_USEDEP}] )
X? (
>=x11-libs/libX11-1.6.2[${MULTILIB_USEDEP}]
>=x11-libs/libXft-2.3.1-r1[${MULTILIB_USEDEP}]
>=x11-libs/libXrender-0.9.8[${MULTILIB_USEDEP}]
)
"
DEPEND="${RDEPEND}
X? ( x11-base/xorg-proto )
"
BDEPEND="
dev-util/glib-utils
virtual/pkgconfig
dev-python/docutils
gtk-doc? (
introspection? (
>=dev-libs/gobject-introspection-1.83.2
dev-util/gi-docgen
)
)
test? ( media-fonts/cantarell )
"
PATCHES=(
"${FILESDIR}/${PN}-1.58.2-clang23-build-fix.patch"
)
src_prepare() {
default
xdg_environment_reset
gnome2_environment_reset
# get rid of a win32 example
rm examples/pangowin32tobmp.c || die
# Skip broken test: https://gitlab.gnome.org/GNOME/pango/-/issues/677
rm tests/layouts/valid-20.layout || die
# Often breaks w/ new harfbuzz (bug #960222)
sed -i -e '/test-font-data/d' tests/meson.build || die
}
multilib_src_configure() {
if use debug; then
append-cflags -DPANGO_ENABLE_DEBUG
else
append-cflags -DG_DISABLE_CAST_CHECKS
fi
local emesonargs=(
# Never use gi-docgen subproject
--wrap-mode nofallback
$(meson_native_use_bool gtk-doc documentation)
$(meson_native_use_feature introspection)
-Dman-pages=true
$(meson_use test build-testsuite)
-Dbuild-examples=false
-Dfontconfig=enabled
$(meson_feature sysprof)
$(meson_native_use_feature libthai)
-Dcairo=enabled
$(meson_feature X xft)
-Dfreetype=enabled
)
meson_src_configure
}
multilib_src_install_all() {
if use examples; then
dodoc -r examples
fi
if use gtk-doc; then
mkdir -p "${ED}"/usr/share/gtk-doc/html/ || die
mv "${ED}"/usr/share/doc/Pango* "${ED}"/usr/share/gtk-doc/html/ || die
fi
}
|
